名前¶

DBD::SQLite - DBI ドライバでの自己完結型(Self Contained)RDBMS

(訳注: (TBR)がついている段落は「みんなの自動翻訳＠TexTra」による 機械翻訳です。)

概要¶

  use DBI;
  my $dbh = DBI->connect("dbi:SQLite:dbname=$dbfile","","");

説明¶

SQLite は、パブリックドメインのファイルベースの関係データベースエンジンで、 この URL で見つけることが出来ます: http://www.sqlite.org/

DBD::SQLite は、全てのものをディストリビューションに含んでいる、 SQLite のための Perl DBI ドライバです。 そのためあなたの perl プロジェクトのために、高速の トランザクション可能な RDBMS を動かすためには、単にこのモジュールを インストールすることだけが必要です。 他には 何もありません。

SQLiteは以下の機能をサポートしています:

Implements a large subset of SQL92

(SQL92 のサブセットの多くを実装)

See http://www.sqlite.org/lang.html for details.

詳細は http://www.sqlite.org/lang.html をご覧ください。

A complete DB in a single disk file

(単一のディスクファイルでの完全な DB)

Everything for your database is stored in a single disk file, making it easier to move things around than with DBD::CSV.

あなたのデータベースのための全ては一つのディスクファイルに格納されます。 これにより DBD::CSV よりも簡単に動かすことが出来ます。

Atomic commit and rollback

(アトミックなコミットとロールバック)

Yes, DBD::SQLite is small and light, but it supports full transactions!

そうです、DBD::SQLite は小さく、軽量ですが、 完全なトランザクションをサポートします。

Extensible

User-defined aggregate or regular functions can be registered with the SQL parser.

ユーザー定義の集計関数または標準関数は、SQLパーサーに登録できます。 (TBR)

これ以上のものがありますが、 そのため SQL の詳細については、上に挙げた SQLite web ページにある ドキュメントを参照してください。 また、DBI 自身の使い方に関する詳細については DBI を参照してください。 API はほぼ各 DBI モジュールがするように機能します。 しかし、現在の所多くの文属性は、未実装であったり、SQLite データベースには 型がないという性質から制限されています。

NOTABLE DIFFERENCES FROM OTHER DRIVERS¶

Database Name Is A File Name¶

SQLiteでは、データベースごとにファイルが作成されます。 データベースファイルのpath(親ディレクトリの有無にかかわらず)をDBI接続文字列に(データベースnameとして)渡す必要があります: (TBR)

  my $dbh = DBI->connect("dbi:SQLite:dbname=$dbfile","","");

ファイルは読み取り/書き込みモードで開かれ、まだ存在しない場合は作成されます。 (TBR)

データベースは1つのファイルに格納されますが、ライブラリによって複数の一時ファイルが作成されるため、データベースファイルを含むディレクトリはSQLiteによって書き込み可能である必要があります。 (TBR)

ファイル名$dbfileが":memory:"の場合、接続用にプライベートな一時的なメモリー内データベースが作成されます。 このメモリー内データベースは、データベース接続が閉じられると消去されます。 これはライブラリのテストに便利です。 (TBR)

SQLiteの将来のバージョンでは、「:」文字で始まる追加の特殊なファイル名が使用される可能性があることに注意してください。 データベースファイル名が実際に「:」文字で始まる場合は、あいまいさを避けるために、ファイル名の前に「./」などのパス名を付けることをお薦めします。 (TBR)

ファイル名$dbfileが空の文字列の場合、プライベートな一時的なオンディスクデータベースが作成されます。 このプライベートデータベースは、データベース接続が閉じられるとすぐに自動的に削除されます。 (TBR)

Accessing A Database With Other Tools¶

コマンドラインからデータベースにアクセスするためには、DBI::Shell モジュールに 入っている dbish を試してみてください。 以下のようにタイプして:

  dbish dbi:SQLite:foo.db

コマンドラインでファイル foo.db にアクセスします。

代わりとして、上記のリンクから DBD::SQLite にぶつかることなく SQLite を インストールし、提供される sqlite コマンドラインツールを使うことが 出来ます。

Blobs¶

バージョン1.11では、blobはSQLiteではテキスト列として「動作する」はずです。 ただし、これによりデータが文字列として扱われるため、length(x)などのSQL文は、バイト単位のblobのサイズではなく、NULで終了する文字列として列の長さを返します。 BLOBとしてネイティブに格納するには、次のコードを使用します: (TBR)

  use DBI qw(:sql_types);
  my $dbh = DBI->connect("dbi:SQLite:dbfile","","");
  
  my $blob = `cat foo.jpg`;
  my $sth = $dbh->prepare("INSERT INTO mytable VALUES (1, ?)");
  $sth->bind_param(1, $blob, SQL_BLOB);
  $sth->execute();

そして検索は機能します (TBR)

  $sth = $dbh->prepare("SELECT * FROM mytable WHERE id = 1");
  $sth->execute();
  my $row = $sth->fetch;
  my $blobo = $row->[1];
  
  # now $blobo == $blob

Functions And Bind Parameters¶

この記事を書いている時点では、関数の戻り値を数値バインド値と比較するSQLは、期待したようには動作しません。 (TBR)

  my $sth = $dbh->prepare(q{
    SELECT bar FROM foo GROUP BY bar HAVING count(*) > ?;
  });
  $sth->execute(5);

これは、DBD::SQLiteでは、デフォルトですべてのバインド値がテキストである(引用符で囲む必要がある)と想定されているためです。 そのため、上記のステートメントを実行すると、次のようになります。 (TBR)

  SELECT bar FROM foo GROUP BY bar HAVING count(*) > "5";

これには、2つの回避策があります。 (TBR)

Use bind_param() explicitly

As shown above in the BLOB section, you can always use bind_param() to tell the type of a bind value.

上記のBLOBセクションで示したように、bind_param()を使用してバインド値のタイプを指定できます。 (TBR)

  use DBI qw(:sql_types);  # Don't forget this
  
  my $sth = $dbh->prepare(q{
    SELECT bar FROM foo GROUP BY bar HAVING count(*) > ?;
  });
  $sth->bind_param(1, 5, SQL_INTEGER);
  $sth->execute();

Add zero to make it a number

This is somewhat weird, but works anyway.

これは少し奇妙ですが、とにかく機能します。 (TBR)

  my $sth = $dbh->prepare(q{
    SELECT bar FROM foo GROUP BY bar HAVING count(*) > (? + 0);
  });
  $sth->execute(5);

Foreign Keys¶

覚悟しろ!オオカミ接近! (TBR)

SQLiteは3.6.19(2009年10月14日にリリースされ、DBD::SQLite 1.26_05にバンドルされている)から外部キー制約のサポートを開始した。 正確には、SQLiteは長い間外部キーを使用してスキーマを解析することができたが、制約は強制されていなかった。 これで、プラグマを実際に発行してこの機能を有効にし、制約を強制することができる。 (TBR)

これを行うには、次のプラグマ(下記参照)を発行します。 トランザクション中ではなく、データベースに接続した直後に発行することをお勧めします。 (TBR)

  $dbh->do("PRAGMA foreign_keys = ON");

また、プラグマをオフにすることで、いつでもこの機能を明示的に無効にすることができます。 (TBR)

  $dbh->do("PRAGMA foreign_keys = OFF");

この記事を書いている時点では、SQLiteチームと私たちは、後方互換性を確保するために、この機能をデフォルトで無効にしています。 これは、この機能があなたのアプリケーションを破壊する可能性があり、実際に私たちのためにいくつか破壊したからです。 外部キーの制約を持つスキーマを使用したことがあっても、それをあまり気にしておらず、SQLiteでは常に無視されると想定している場合は、準備して、外部キーのサポートがデフォルトで有効になっている場合でもアプリケーションが動作し続けることを保証するために、広範なテストを行ってください。 SQLiteチームが将来的にデフォルトでオンにする可能性は非常に高く、私たちは彼らがそうするまでにそれを行う予定です。 (TBR)

詳細はhttp://www.sqlite.org/foreignkeys.htmlをご覧ください。 (TBR)

Pragma¶

SQLiteには、操作を変更したり、内部データを照会したりするための「プラグマ」のセットがあります。 これらはSQLiteに固有のもので、他のDBDライブラリでは動作しないようですが、これらのいくつかは非常に便利です。 DBD::SQLiteは、データベースに接続するときに、実際にいくつか(show_datatypesなど)を設定します。 詳細はhttp://www.SQLite.org/pragma.htmlを参照してください。 (TBR)

Transactions¶

DBI/DBD::SQLiteのトランザクションは少し混乱しているかもしれません。 これらは、AutoCommitフラグのステータスに応じて動作が異なります。 (TBR)

When the AutoCommit flag is on

You're supposed to always use the auto-commit mode, except you explicitly begin a transaction, and when the transaction ended, you're supposed to go back to the auto-commit mode. To begin a transaction, call begin_work method, or issue a BEGIN statement. To end it, call commit/rollback methods, or issue the corresponding statements.

トランザクションを明示的に開始し、トランザクションが終了したときに自動コミットモードに戻る場合を除き、常に自動コミットモードを使用する必要があります。 トランザクションを開始するには、begin_workメソッドをコールするか、BEGIN文を発行します。 トランザクションを終了するには、commit/rollbackメソッドをコールするか、対応する文を発行します。 (TBR)

  $dbh->{AutoCommit} = 1;
  
  $dbh->begin_work; # or $dbh->do('BEGIN TRANSACTION');
  
  # $dbh->{AutoCommit} is turned off temporarily during a transaction;
  
  $dbh->commit; # or $dbh->do('COMMIT');
  
  # $dbh->{AutoCommit} is turned on again;

When the AutoCommit flag is off

You're supposed to always use the transactinal mode, until you explicitly turn on the AutoCommit flag. You can explicitly issue a BEGIN statement (only when an actual transaction has not begun yet) but you're not allowed to call begin_work method (if you don't issue a BEGIN, it will be issued internally). You can commit or roll it back freely. Another transaction will automatically begins if you execute another statement.

AutoCommitフラグを明示的にオンにするまでは、常にtransactinalモードを使用する必要があります。 BEGIN文は明示的に発行できますが(実際のトランザクションがまだ開始されていない場合のみ)、begin_workメソッドをコールすることはできません(BEGINを発行しない場合は、内部的に発行されます)。 コミットまたはロールバックは自由に実行できます。 別の文を実行すると、別のトランザクションが自動的に開始されます。 (TBR)

  $dbh->{AutoCommit} = 0;
  
  # $dbh->do('BEGIN TRANSACTION') is not necessary, but possible
  
  ...
  
  $dbh->commit; # or $dbh->do('COMMIT');
  
  # $dbh->{AutoCommit} stays intact;
  
  $dbh->{AutoCommit} = 1;  # ends the transactional mode

このAutoCommitモードは、内部SQLiteライブラリのオートコミットモードから独立しています。 オートコミットモードは常にBEGIN文で始まり、COMMITまたは<ROLLBACK>で終わります。 (TBR)

性能¶

SQLite は高速です、非常に高速です。 Matt は、私の 72MB のログファイルをそれで処理しました。 単純に 1000 行毎にコミットしながら(そうでなければ挿入がとても遅くなります)、 トランザクションを使ってデータ(400,000 以上の行)を挿入し、 そのデータに問い合わせを実行しました。

count(*) と avg(bytes) のような問い合わせは、たちまち返ってきました。 しかし何より彼が驚いたことは:

  SELECT url, count(*) as count
  FROM access_log
  GROUP BY url
  ORDER BY count desc
  LIMIT 20

サイト (http://axkit.org) にヒットし たURL のトップ 20 を 見つけることでした。 これを 2 秒以内で返しました。 彼は真剣に私のログ解析コードを、この小さな スピードの魔物を使うように変更することを考えています。

そうそう、テーブルにはインデックスをつけていませんし、400MHz PIII の上です。

パフォーマンスを最高にするためには、linux を使っているのであれば、 hdparam のセッティングを確実にチューンしてください。 またこのように設定したいかもしれません:

  PRAGMA default_synchronous = OFF

これは、いくらかの心配を犠牲にすることで、トランザクションを使わない 書込みを非常に遅くしてしまう fsync がすることから、sqlite を保護します。 cache_size pragma でも楽しんでみるようにしてください。

SQLiteのメモリ使用量は、cache_sizeプラグマを使用して調整することもできます。 (TBR)

  $dbh->do("PRAGMA cache_size = 800000");

上記はDBキャッシュに800Mを割り当てます。 デフォルトは2Mです。 あなたのスイートスポットはおそらくその間のどこかにあります。 (TBR)

DRIVER PRIVATE ATTRIBUTES¶

Database Handle Attributes¶

sqlite_version

Returns the version of the SQLite library which DBD::SQLite is using, e.g., "2.8.0". Can only be read.

DBD::SQLiteが使用しているSQLiteライブラリのバージョン("2.8.0"など)を返します。 読み取り専用です。 (TBR)

sqlite_unicode

If set to a true value, DBD::SQLite will turn the UTF-8 flag on for all text strings coming out of the database (this feature is currently disabled for perl < 5.8.5). For more details on the UTF-8 flag see perlunicode. The default is for the UTF-8 flag to be turned off.

trueに設定すると、DBD::SQLiteは、データベースから出力されるすべてのテキスト文字列に対してUTF-8フラグをオンにします(perl<5.8.5では、この機能は現在無効になっています)。 UTF-8フラグの詳細については、perlunicodeを参照してください。 デフォルトでは、UTF-8フラグはオフになっています。 (TBR)

Also note that due to some bizarreness in SQLite's type system (see http://www.sqlite.org/datatype3.html), if you want to retain blob-style behavior for some columns under $dbh->{sqlite_unicode} = 1 (say, to store images in the database), you have to state so explicitly using the 3-argument form of "bind_param" in DBI when doing updates:

また、SQLiteの型システム(http://www.SQLite.org/datatype3.htmlを参照)のいくつかの奇妙さのために、$dbh->{SQLite_unicode}=1>>の下のsome列のブロブスタイルの動作を保持したい場合(たとえば、イメージをデータベースに格納する場合)、更新を行うときに"bind_param" in DBIの3引数形式を使用して明示的に宣言する必要があることにも注意してください。 (TBR)

  use DBI qw(:sql_types);
  $dbh->{sqlite_unicode} = 1;
  my $sth = $dbh->prepare("INSERT INTO mytable (blobcolumn) VALUES (?)");
  
  # Binary_data will be stored as is.
  $sth->bind_param(1, $binary_data, SQL_BLOB);

Defining the column type as BLOB in the DDL is not sufficient.

DDLで列タイプをBLOBとして定義することは、notで十分です。 (TBR)

This attribute was originally named as unicode, and renamed to sqlite_unicode for integrity since version 1.26_06. Old unicode attribute is still accessible but will be deprecated in the near future.

この属性は元々unicodeという名前でしたが、バージョン1.26_06から整合性のためにsqlite_unicodeに名前が変更されました。 古いunicode属性はまだアクセス可能ですが、近い将来廃止される予定です。 (TBR)

メソッド¶

table_info¶

  $sth = $dbh->table_info(undef, $schema, $table, $type, \%attr);

"table_info" in DBIで指定されたすべての表およびスキーマ(データベース)が戻されます。 スキーマおよび表の引数により、LIKE検索が実行されます。 \%attrに'Escape'属性を含めることにより、ESCAPE文字を指定できます。 $type引数には、'TABLE'、'VIEW'、'LOCAL TEMPORARY'、および'SYSTEM TABLE'タイプのカンマ区切りリストを指定できます(デフォルトではすべてが戻されます)。 表の直接リストではなく、文ハンドルが戻されることに注意してください。 (TBR)

次のフィールドが返されます。 (TBR)

TABLE_CAT:SQLiteにはカタログの概念がないため、常にNULLです。 (TBR)

TABLE_SCHEMA:表またはビューが存在するスキーマ(データベース)の名前。 デフォルトのスキーマは'main'、一時表は'temp'、その他のデータベースはデータベースが接続されたときに指定された名前になります。 (TBR)

TABLE_NAME:テーブルまたはビューの名前。 (TBR)

TABLE_TYPE:戻されるオブジェクトのタイプ。 'TABLE'、'VIEW'、'LOCAL TEMPORARY'、または'SYSTEM TABLE'のいずれかです。 (TBR)

DRIVER PRIVATE METHODS¶

次のメソッドは、少しひねりを加えてfunc()メソッドを介して呼び出すことができますが、DBIの作成者は、さまざまな理由からfunc()メソッドの使用を推奨していません(詳細については、DBIの文書http://search.cpan.org/dist/DBI/lib/DBI/DBD.pm#Using_install_method()_to_expose_driver-private_methodsを参照してください)。 したがって、DBI>=1.608を使用している場合は、これらのsqlite_メソッドを使用します。 古いDBIを使用する必要がある場合は、次のように呼び出すことができます: (TBR)

  $dbh->func( ..., "(method name without sqlite_ prefix)" );

$dbh->sqlite_last_insert_rowid()¶

このメソッドは最後に挿入された rowid を返します。 もし INTEGER PRIMARY KEY をあなたのテーブルでの先頭カラムとして指定すれば、 返されるのはそのカラムになります。 そうでなければ、それは隠された ROWID カラムになります。 詳細については sqlite ドキュメントをご覧ください。

通常、このメソッドは使用しません。 かわりにDBIlast_insert_idメソッドを使用します。 このメソッドの使用方法は次のとおりです: (TBR)

  $h->last_insert_id($catalog, $schema, $table_name, $field_name [, \%attr ])

$h->last_insert_id("","","","")を実行することは、$dbh->sqlite_last_insert_rowid()を直接実行することと同じです。 (TBR)

$dbh->sqlite_busy_timeout()¶

現在のビジータイムアウトを取得します。 (TBR)

$dbh->sqlite_busy_timeout( $ms )¶

現在のビジータイムアウトを設定します。 タイムアウトはミリ秒単位です。 (TBR)

$dbh->sqlite_create_function( $name, $argc, $code_ref )¶

このメソッドは、SQLクエリで使用できる新しい関数を登録します。 メソッドのパラメータは次のとおりです。 (TBR)

$name

The name of the function. This is the name of the function as it will be used from SQL.

関数の名前。 これはSQLから使用される関数の名前です。 (TBR)

$argc

The number of arguments taken by the function. If this number is -1, the function can take any number of arguments.

関数が取る引数の数。 この数が-1の場合、関数は任意の数の引数を取ることができます。 (TBR)

$code_ref

This should be a reference to the function's implementation.

これは、関数の実装への参照である必要があります。 (TBR)

たとえば、エポックからの現在の秒数を返すnow()関数を定義する方法を次に示します。 (TBR)

  $dbh->sqlite_create_function( 'now', 0, sub { return time } );

この後、SQLから次のように使用できます。 (TBR)

  INSERT INTO mytable ( now() );

REGEXP function¶

SQLiteには、インフィックス演算子'REGEXP'の構文サポートが含まれていますが、実装はありません。 DBD::SQLiteドライバは、現在のロケールを使用して、標準的なperl正規表現の照合を実行する実装を自動的に登録します。 したがって、たとえば、次のようなクエリを使用して、'A'で始まる単語を検索できます。 (TBR)

  SELECT * from table WHERE column REGEXP '\bA\w+'

大文字と小文字を区別しない検索が必要な場合は、次のようにperl regexフラグを使用します。 (TBR)

  SELECT * from table WHERE column REGEXP '(?i:\bA\w+)'

デフォルトのREGEXP実装は、前述のcreate_functionAPIを介して上書きできます。 (TBR)

正規表現マッチングはSQLiteインデックスを使用<しません>しますが、すべての行に対して繰り返されるため、パフォーマンスの点で非常にコストがかかる可能性があることに注意してください。 (TBR)

$dbh->sqlite_create_collation( $name, $code_ref )¶

このメソッドは、SQLクエリーでソート用のCOLLATEオプションとして使用できる新しい関数を手動で登録します。 このような関数は、必要に応じて自動的に登録することもできます。 後述のセクション"COLLATION FUNCTIONS"を参照してください。 (TBR)

このメソッドのパラメータは次のとおりです。 (TBR)

$name

The name of the function exposed to SQL.

SQLに公開されている関数の名前。 (TBR)

$code_ref

Reference to the function's implementation. The driver will check that this is a proper sorting function.

関数の実装への参照。 ドライバは、これが適切なソート関数であることを確認します。 (TBR)

$dbh->sqlite_collation_needed( $code_ref )¶

このメソッドは、SQL文から未定義の照合順序が要求されるたびに起動されるコールバック関数を手動で登録します。 コールバックは次のように起動されます。 (TBR)

  $code_ref->($dbh, $collation_name)

"sqlite_create_collation"を使用して目的の照合を登録する必要があります。 (TBR)

最初のコールバックはすでにDBD::SQLiteによって登録されているため、ほとんどの一般的なケースでは、%DBD::SQLite::COLLATIONハッシュに照合順序を追加する方が簡単です(後述のセクション"COLLATION FUNCTIONS"を参照)。 (TBR)

$dbh->sqlite_create_aggregate( $name, $argc, $pkg )¶

このメソッドは、SQLから使用できる新しい集計関数を登録します。 メソッドのパラメータは次のとおりです。 (TBR)

$name

The name of the aggregate function, this is the name under which the function will be available from SQL.

集約関数の名前。 これは、SQLから使用できる関数の名前です。 (TBR)

$argc

This is an integer which tells the SQL parser how many arguments the function takes. If that number is -1, the function can take any number of arguments.

これは、関数が取る引数の数をSQLパーサーに伝える整数です。 その数が-1の場合、関数は任意の数の引数を取ることができます。 (TBR)

$pkg

This is the package which implements the aggregator interface.

これは、アグリゲータインタフェースを実装するパッケージです。 (TBR)

アグリゲータインタフェースは、次の3つのメソッドの定義で構成されています。 (TBR)

new()

This method will be called once to create an object which should be used to aggregate the rows in a particular group. The step() and finalize() methods will be called upon the reference return by the method.

このメソッドは、特定のグループ内の行を集計するために使用するオブジェクトを作成するために1回コールされます。 step()およびfinalize()メソッドは、メソッドからの参照が返されたときにコールされます。 (TBR)

step(@_)

This method will be called once for each row in the aggregate.

このメソッドは、集約の各行に対して1回ずつ呼び出されます。 (TBR)

finalize()

This method will be called once all rows in the aggregate were processed and it should return the aggregate function's result. When there is no rows in the aggregate, finalize() will be called right after new().

このメソッドは、集計のすべての行が処理されると呼び出され、集計関数の結果を返す必要があります。 集計に行がない場合は、new()の直後にfinalize()が呼び出されます。 (TBR)

次に、分散を返す単純な集約関数を示します(pysqliteから採用された例)。 (TBR)

  package variance;
  
  sub new { bless [], shift; }
  
  sub step {
      my ( $self, $value ) = @_;
  
      push @$self, $value;
  }
  
  sub finalize {
      my $self = $_[0];
  
      my $n = @$self;
  
      # Variance is NULL unless there is more than one row
      return undef unless $n || $n == 1;
  
      my $mu = 0;
      foreach my $v ( @$self ) {
          $mu += $v;
      }
      $mu /= $n;
  
      my $sigma = 0;
      foreach my $v ( @$self ) {
          $sigma += ($x - $mu)**2;
      }
      $sigma = $sigma / ($n - 1);
  
      return $sigma;
  }
  
  $dbh->sqlite_create_aggregate( "variance", 1, 'variance' );

集約関数は、次のように使用できます。 (TBR)

  SELECT group_name, variance(score)
  FROM results
  GROUP BY group_name;

その他の例については、DBD::SQLite::Cookbookを参照してください。 (TBR)

$dbh->sqlite_progress_handler( $n_opcodes, $code_ref )¶

このメソッドは、長時間実行されるSQLiteの呼び出し中に定期的に呼び出されるハンドラを登録します。 (TBR)

このインタフェースの使用例としては、大規模なクエリーの実行中にGUIを更新しておくことが挙げられます。 パラメータは次のとおりです。 (TBR)

$n_opcodes

The progress handler is invoked once for every $n_opcodes virtual machine opcodes in SQLite.

progressハンドラは、SQLiteの$n_opcodes仮想マシンのオペコードごとに1回呼び出されます。 (TBR)

$code_ref

Reference to the handler subroutine. If the progress handler returns non-zero, the SQLite operation is interrupted. This feature can be used to implement a "Cancel" button on a GUI dialog box.

ハンドラサブルーチンへの参照。 進行状況ハンドラがゼロ以外を返す場合、SQLite操作は中断されます。 この機能を使用して、GUIダイアログボックスに「キャンセル」ボタンを実装できます。 (TBR)

Set this argument to undef if you want to unregister a previous progress handler.

以前の進捗ハンドラの登録を解除する場合は、この引数をundefに設定します。 (TBR)

$dbh->sqlite_commit_hook( $code_ref )¶

このメソッドは、トランザクションがコミットされるたびに呼び出されるコールバック関数を登録します。 以前のsqlite_commit_hookの呼び出しによって設定されたコールバックはすべて上書きされます。 以前のコールバックへの参照(存在する場合)が返されます。 undefを登録すると、コールバックが無効になります。 (TBR)

コミットフックコールバックがゼロを返すと、コミット操作は正常に続行できます。 コールバックがゼロ以外を返すと、コミットはロールバックに変換されます(その場合、後で$dbh->rollback()>>を<明示的に>呼び出そうとすると、エラーが発生します)。 (TBR)

$dbh->sqlite_rollback_hook( $code_ref )¶

このメソッドは、トランザクションがロールバックされるたびに呼び出されるコールバック関数を登録します。 以前のsqlite_rollback_hookの呼び出しによって設定されたコールバックはすべて上書きされます。 以前のコールバックへの参照(存在する場合)が返されます。 undefを登録すると、コールバックが無効になります。 (TBR)

$dbh->sqlite_update_hook( $code_ref )¶

このメソッドは、行が更新、挿入、または削除されるたびに呼び出されるコールバック関数を登録します。 以前のsqlite_update_hookの呼び出しによって設定されたコールバックはすべて上書きされます。 以前のコールバックへの参照(存在する場合)が返されます。 undefを登録すると、コールバックが無効になります。 (TBR)

コールバックは次のように呼び出されます。 (TBR)

  $code_ref->($action_code, $database, $table, $rowid)

ここで (TBR)

$action_code

is an integer equal to either DBD::SQLite::INSERT, DBD::SQLite::DELETE or DBD::SQLite::UPDATE (see "Action Codes");

DBD::SQLite::INSERT、DBD::SQLite::DELETE、またはDBD::SQLite::UPDATE("Action Codes"を参照)のいずれかと等しい整数です。 (TBR)

$database

is the name of the database containing the affected row;

は、影響を受ける行を含むデータベースの名前です。 (TBR)

$table

is the name of the table containing the affected row;

は、影響を受ける行を含むテーブルの名前です。 (TBR)

$rowid

is the unique 64-bit signed integer key of the affected row within that table.

は、そのテーブル内の影響を受けるローの一意の64ビット符号付き整数キーです。 (TBR)

$dbh->sqlite_set_authorizer( $code_ref )¶

このメソッドは、"prepare" in DBIメソッドによってSQL文がコンパイルされるたびに呼び出される承認者コールバックを登録します。 承認者コールバックは、アクションを許可する場合はDBD::SQLite::OK、特定のアクションを禁止するがSQL文のコンパイルを続行する場合はDBD::SQLite::IGNORE、またはSQL文全体をエラーで拒否する場合はDBD::SQLite::DENYを返す必要があります。 承認者コールバックがその他の値を返す場合、承認者をトリガーしたprepare呼び出しはエラーメッセージで失敗します。 (TBR)

承認者は、信頼できないソースからSQL文を準備するときに、SQL文が表示を許可されていないデータにアクセスしようとしたり、データベースに損害を与える悪意のある文を実行しようとしたりしないようにするために使用されます。 たとえば、アプリケーションでは、データベースによる評価のためにユーザーが任意のSQL問合せを入力できるようにする場合があります。 ただし、アプリケーションでは、ユーザーがデータベースに任意の変更を加えられないようにする必要があります。 承認者は、SELECT文以外のすべてを禁止するユーザー入力SQLが準備されている間に配置できます。 (TBR)

コールバックは次のように呼び出されます。 (TBR)

  $code_ref->($action_code, $string1, $string2, $database, $trigger_or_view)

ここで (TBR)

$action_code

is an integer that specifies what action is being authorized (see "Action Codes").

は、許可されているアクションを指定する整数です("Action Codes"を参照)。 (TBR)

$string1, $string2

are strings that depend on the action code (see "Action Codes").

は、アクションコードに依存する文字列です("Action Codes"を参照)。 (TBR)

$database

is the name of the database (main, temp, etc.) if applicable.

は、データベースの名前です(main、tempなど)。 (TBR)

$trigger_or_view

is the name of the inner-most trigger or view that is responsible for the access attempt, or undef if this access attempt is directly from top-level SQL code.

は、アクセス試行の原因となった最も内側のトリガまたはビューの名前です。 アクセス試行がトップレベルのSQLコードから直接行われた場合は、undefです。 (TBR)

$dbh->sqlite_backup_from_file( $filename )¶

このメソッドはSQLite Online Backup APIにアクセスし、指定されたデータベースファイルのバックアップを取得し、現在のデータベース接続にコピーして上書きします。 これは、現在の接続が特別な:memory:データベースであり、既存のDBからデータを入力する場合に特に便利です。 (TBR)

$dbh->sqlite_backup_to_file( $filename )¶

このメソッドはSQLite Online Backup APIにアクセスし、現在接続されているデータベースのバックアップを取得して、指定されたファイルに書き出します。 (TBR)

$dbh->sqlite_enable_load_extension( $bool )¶

true値を指定してこのメソッドを呼び出すと、(外部)sqlite3拡張機能を読み込むことができます。 呼び出し後、次のように拡張機能を読み込むことができます。 (TBR)

  $dbh->sqlite_enable_load_extension(1);
  $sth = $dbh->prepare("select load_extension('libsqlitefunctions.so')")
  or die "Cannot prepare: " . $dbh->errstr();

DRIVER CONSTANTS¶

SQLite C定数のサブセットは、Perlで使用できるようになっています。 これは、フックや承認コールバックを作成するときに必要になる可能性があるためです。 このような定数にアクセスするには、コンパイル時にDBD::Sqliteモジュールを明示的にusedにする必要があります。 たとえば、DELETE操作を禁止する承認は、次のように記述されます。 (TBR)

  use DBD::SQLite;
  $dbh->sqlite_set_authorizer(sub {
    my $action_code = shift;
    return $action_code == DBD::SQLite::DELETE ? DBD::SQLite::DENY
                                               : DBD::SQLite::OK;
  });

DBD::SQLiteで実装されている定数の一覧を以下に示します。 詳細については、http://www.sqlite.org/c3ref/constlist.htmlを参照してください。 (TBR)

Authorizer Return Codes¶

  OK
  DENY
  IGNORE

Action Codes¶

"set_authorizer"メソッドは、特定のSQL文アクションを承認するために呼び出されるコールバック関数を登録します。 コールバックの最初のパラメータは、承認されるアクションを指定する整数コードです。 コールバックの2番目と3番目のパラメータは文字列で、その意味はアクションコードによって異なります。 次に、アクションコードとその関連文字列のリストを示します。 (TBR)

  # constant              string1         string2
  # ========              =======         =======
  CREATE_INDEX            Index Name      Table Name
  CREATE_TABLE            Table Name      undef
  CREATE_TEMP_INDEX       Index Name      Table Name
  CREATE_TEMP_TABLE       Table Name      undef
  CREATE_TEMP_TRIGGER     Trigger Name    Table Name
  CREATE_TEMP_VIEW        View Name       undef
  CREATE_TRIGGER          Trigger Name    Table Name
  CREATE_VIEW             View Name       undef
  DELETE                  Table Name      undef
  DROP_INDEX              Index Name      Table Name
  DROP_TABLE              Table Name      undef
  DROP_TEMP_INDEX         Index Name      Table Name
  DROP_TEMP_TABLE         Table Name      undef
  DROP_TEMP_TRIGGER       Trigger Name    Table Name
  DROP_TEMP_VIEW          View Name       undef
  DROP_TRIGGER            Trigger Name    Table Name
  DROP_VIEW               View Name       undef
  INSERT                  Table Name      undef
  PRAGMA                  Pragma Name     1st arg or undef
  READ                    Table Name      Column Name
  SELECT                  undef           undef
  TRANSACTION             Operation       undef
  UPDATE                  Table Name      Column Name
  ATTACH                  Filename        undef
  DETACH                  Database Name   undef
  ALTER_TABLE             Database Name   Table Name
  REINDEX                 Index Name      undef
  ANALYZE                 Table Name      undef
  CREATE_VTABLE           Table Name      Module Name
  DROP_VTABLE             Table Name      Module Name
  FUNCTION                undef           Function Name
  SAVEPOINT               Operation       Savepoint Name

COLLATION FUNCTIONS¶

Definition¶

SQLite v3は、2つのテキスト値を比較するために使用される、ユーザ定義の「照合シーケンス」または「照合関数」として知られる任意の比較関数をユーザが提供する機能を提供します。 http://www.SQLite.org/datatype3.html#collationは、さまざまなSQL式で照合がどのように使用されるかを説明しています。 (TBR)

Builtin collation sequences¶

SQLiteには、次の照合順序が組み込まれています。 (TBR)

BINARY

Compares string data using memcmp(), regardless of text encoding.

テキストのエンコーディングに関係なく、memcmp()を使用して文字列データを比較します。 (TBR)

NOCASE

The same as binary, except the 26 upper case characters of ASCII are folded to their lower case equivalents before the comparison is performed. Note that only ASCII characters are case folded. SQLite does not attempt to do full UTF case folding due to the size of the tables required.

バイナリと同じですが、比較が実行される前に、ASCIIの26個の大文字が対応する小文字に折りたたまれます。 ASCII文字のみ大文字と小文字が折りたたまれることに注意してください。 SQLiteでは、必要なテーブルのサイズのために、UTFの完全な大文字と小文字の折りたたみは行われません。 (TBR)

RTRIM

The same as binary, except that trailing space characters are ignored.

バイナリと同じですが、末尾のスペース文字は無視されます。 (TBR)

さらに、DBD::SQLiteは次の照合順を自動的にインストールします。 (TBR)

perl

corresponds to the Perl cmp operator

Perl cmp演算子に対応します。 (TBR)

perllocale

Perl cmp operator, in a context where use locale is activated.

Perl cmp演算子。 use localeがアクティブになっているコンテキストで使用します。 (TBR)

Usage¶

たとえば、次のように記述できます。 (TBR)

  CREATE TABLE foo(
      txt1 COLLATE perl,
      txt2 COLLATE perllocale,
      txt3 COLLATE nocase
  )

または (TBR)

  SELECT * FROM foo ORDER BY name COLLATE perllocale

Unicode handling¶

属性$dbh->{sqlite_unicode}>>が設定されている場合、データベースから来て照合関数に渡される文字列は、utf8フラグで適切にタグ付けされます。 しかし、これはperl照合シーケンスの最初の呼び出しで、sqlite_unicode属性がbeforeに設定されている場合にのみ動作します。 ユニコードを有効にするための推奨方法は、接続時にパラメータを設定することです。 (TBR)

  my $dbh = DBI->connect(
      "dbi:SQLite:dbname=foo", "", "",
      {
          RaiseError     => 1,
          sqlite_unicode => 1,
      }
  );

Adding user-defined collations¶

ユーザ定義の照合を追加するためのネイティブSQLite APIは、メソッド"SQLite_create_collation"および"SQLite_collation_needed"を介して公開されます。 (TBR)

$dbhハンドルが作成されるたびにこれらの関数を呼び出すことを避けるために、DBD::SQLiteは%DBD::SQLite::COLLATIONハッシュを介してより簡単なインタフェースを提供します。 そのハッシュに独自の照合関数を挿入するだけで、SQLで不明な照合名が検出されるたびに、適切な照合関数がハッシュからオンデマンドでロードされます。 たとえば、アクセント記号付き文字に関係なくテキスト値をソートする方法を次に示します。 (TBR)

  use DBD::SQLite;
  $DBD::SQLite::COLLATION{no_accents} = sub {
    my ( $a, $b ) = map lc, @_;
    tr[珥痲繝苣蒻蜍跪迴髓揭淝瞀觔釻]
      [aaaaaacdeeeeiiiinoooooouuuuy] for $a, $b;
    $a cmp $b;
  };
  my $dbh  = DBI->connect("dbi:SQLite:dbname=dbfile");
  my $sql  = "SELECT ... FROM ... ORDER BY ... COLLATE no_accents");
  my $rows = $dbh->selectall_arrayref($sql);

組み込みのperlまたはperllocale照合は、同じハッシュで事前に定義されています。 (TBR)

COLLATIONハッシュは、現在のプロセス内のグローバルレジストリであるため、望ましくない副作用のリスクがあります。 したがって、遠距離でのアクションを防ぐために、ハッシュは「書き込み専用」ハッシュとして実装され、新しいエントリを受け入れますが、既存のエントリ(組み込みのperlおよびperllocaleを含む)を上書きまたは削除しようとすると例外が発生します。 (TBR)

本当に本当にエントリを変更または削除する必要がある場合は、%DBD::SQLite::COLLATIONの下にあるタイオブジェクトをいつでも取得できますが、自分が何をしているのかを本当に知っている場合以外は取得しないでください。 また、グローバルハッシュを変更しても、既存のデータベースハンドル内の既存の照合は変更されません。 照合の新しいrequestsにのみ影響します。 つまり、既存の$dbh内の照合の動作を変更する場合は、"create_collation"メソッドを直接呼び出す必要があります。 (TBR)

TO DO¶

次の項目を実行する必要があります。 (TBR)

Warnings Upgrade¶

私たちは現在、警告を発して抑制するために、おぞましいほど巧妙な方法を使用しています。 今のところはそれで十分ですが、かろうじてです。 (TBR)

すべての警告コードを移行して、推奨されるDBI警告を使用します。 (TBR)

Leak Detection¶

AUTOMATED_TESTINGおよびRELEASE_TESTING中にのみ実行されるリーク検出テストを1つ以上実装し、リークを処理するCコードがないことを検証します。 (TBR)

Stream API for Blobs¶

sqlite2_blob_open/sqlite2_blob_closeを使用したBLOBの読み込み/書き込み。 (TBR)

Flags for sqlite3_open_v2¶

sqlite3_open_v2の完全なAPI(ファイルを開くためのフラグ)をサポートします。 (TBR)

サポート¶

バグは、次の場所にあるCPANバグトラッカを介して報告する必要があります。 (TBR)

http://rt.cpan.org/NoAuth/ReportBug.html?Queue=DBD-SQLite (TBT)

バンドルされているsqliteライブラリのバグ(sqlite3.[ch]のバグなど)は、sqlite.orgのsqlite開発者にバグトラッカーまたはメーリングリストを通じて報告する必要があります。 (TBR)

作者¶

Matt Sergeant <[email protected]> (TBT)

Francis J. Lacoste <[email protected]> (TBT)

Wolfgang Sourdeau <[email protected]> (TBT)

Adam Kennedy <[email protected]> (TBT)

Max Maischein <[email protected]> (TBT)

Laurent Dami <[email protected]> (TBT)

Kenichi Ishigaki <[email protected]> (TBT)

コピーライト¶

The bundled SQLite code in this distribution is Public Domain. (TBT)

DBD::SQLite is copyright 2002 - 2007 Matt Sergeant. (TBT)

Some parts copyright 2008 Francis J. Lacoste. (TBT)

Some parts copyright 2008 Wolfgang Sourdeau. (TBT)

Some parts copyright 2008 - 2010 Adam Kennedy. (TBT)

Some parts derived from DBD::SQLite::Amalgamation copyright 2008 Audrey Tang. (TBT)

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself. (TBT)

The full text of the license can be found in the LICENSE file included with this module. (TBT)

POD ERRORS¶

Hey! The above document had some coding errors, which are explained below:

Around line 711:

Unterminated C< ... > sequence

Around line 1386:

Unterminated C< ... > sequence

Around line 1903:

Unterminated C< ... > sequence