名前¶

perlfaq9 - Web、メール、ネットワーク

説明¶

このセクションでは、web サイトの実行、メールの送受信、および一般的な ネットワークに関する質問を扱っています。

web フレームワークを使うべき?¶

はい。 何らかのレベルの相互作用(フォーム、ユーザー、データベース)を持つ web サイトを 構築しているなら、リクエストとレスポンスをより簡単に扱えるような フレームワークを使いたいでしょう。

相互作用がなくても、HTML ファイル(およびその他の資産)の管理をより 簡単にするために Template Toolkit や Plack::Middleware::TemplateToolkit のようなものを使いたいかもしれません。

どの web フレームワークを使うべき?¶

この質問への単純な答えはありません。 Perl のフレームワークには、基本的なファイルサーバとスケールの小さい イントラネット用から国際ビジネスのコアとなる巨大国際多言語 web サイトまで あらゆるものがあります。

以下は、特定の要求に合わせて決定を行う助けとなるであろうコメント付きの いくつかのフレームワークの一覧です。 文書を読むことから始めて、それから関連するメーリングリストや IRC チャンネルに質問してください。

Catalyst

Strongly object-oriented and fully-featured with a long development history and a large community and addon ecosystem. It is excellent for large and complex applications, where you have full control over the server.

長い開発の歴史と大きなコミュニティおよびアドオン生態系を持ち、 強力にオブジェクト指向で完全な機能があります。 サーバに対する完全な制御がある場所での大きく複雑なアプリケーションには 素晴らしいものです。

Dancer

Young and free of legacy weight, providing a lightweight and easy to learn API. Has a growing addon ecosystem. It is best used for smaller projects and very easy to learn for beginners.

新しくレガシーな重みから解放されていて、軽量で学習しやすい API を提供します。 アドオン生態系は大きくなりつつあります。 より小さいプロジェクトに最適で初心者が学習するのはとても簡単です。

Mojolicious

Fairly young with a focus on HTML5 and real-time web technologies such as WebSockets.

比較的若く、HTML5 と WebSockets のようなリアルタイム web 技術に焦点を 当てています。

Web::Simple

Currently experimental, strongly object-oriented, built for speed and intended as a toolkit for building micro web apps, custom frameworks or for tieing together existing Plack-compatible web applications with one central dispatcher.

現在の所実験的で、強力にオブジェクト指向で、速度重視で構築されており、 ごく小さい web アプリやカスタムフレームワークを構築したり、 既存の Plack 互換の web アプリケーションを一つの中央ディスパッチャと 結びつけることを意図しています。

これら全ては Plack を使うか相互作用しており、Perl で web サイトを 構築するときは基本を理解する価値があります (多くの有用な Plack::Middleware が あります)。

Plack と PSGI って何?¶

PSGI は Perl Web Server Gateway Interface Specification です; これは多くの Perl web フレームワークが使う標準で、web サイトを構築するためにこれを 理解する必要はないはずです; 使いたい部分は Plack でしょう。

Plack は PSGI スタックを使うためのツールの集合です。 これには Web アプリケーションフレームワークのための ミドルウェア 要素、 リファレンスサーバ、ユーティリティを含みます。 Plack は Ruby の Rack や Python の WSGI のための Paste に似ています。

Plack と独自のコードを使って web サイトを構築することもできますが、 とても基本的な web サイト以外のものなら、(Plack を使った) web フレームワークを使うのがよりよい選択肢です。

ある文字列から HTML を取り除くには?¶

HTML::Strip を使うか、HTML を取り除くだけでなく結果のプレーンテキストを 少し単純な形式にしようとする HTML::FormatText を使ってください。

URL の展開を行うには?¶

HTML::SimpleLinkExtor は HTML から URL を抽出します; これはアンカー、 イメージ、オブジェクト、フレームおよび URL を含んでいるその他の多くのタグを 扱います。 より複雑なものが必要なら、独自の HTML::LinkExtor や HTML::Parser の サブクラスを作ることができます。 何か特別な用途に合わせるための例として HTML::SimpleLinkExtor を使うことも できます。

任意のテキスト文書から URL を抽出するためには、URI::Find が使えます。

HTML ファイルをフェッチするには?¶

(brian d foy によって寄贈されました)

libwww-perl ディストリビューションを使ってください。 LWP::Simple はウェブ上のリソースをフェッチして、その内容を文字列として 返します:

    use LWP::Simple qw(get);

    my $html = get( "http://www.example.com/index.html" );

リソースを直接ファイルに保存することもできます:

    use LWP::Simple qw(getstore);

    getstore( "http://www.example.com/index.html", "foo.html" );

もっと複雑なことをする必要がある場合は、仕事を行うための独自の ユーザーエージェント(例えばブラウザ)を作るために LWP::UserAgent モジュールを使えます。 対話的なウェブブラウザをシミュレートしたい場合は、 WWW::Mechanize モジュールが使えます。

HTML フォームの処理を自動化するには?¶

もし、複数のページとフォームや web サイトを移動するような、複雑なことを しようとしているなら、WWW::Mechanize が使えます。 全ての詳細についてはこれのドキュメントを参照してください。

GET メソッドを使って値を処理しているのであれば、URL を作って、 さらに query_form メソッドを使ってフォームをエンコードします:

    use LWP::Simple;
    use URI::URL;

    my $url = url('L<http://www.perl.com/cgi-bin/cpan_mod')>;
    $url->query_form(module => 'DB_File', readme => 1);
    $content = get($url);

POST メソッドを使っているのであれば、自分用のエージェントを作成して コンテンツを適切にエンコードしてやります。

    use HTTP::Request::Common qw(POST);
    use LWP::UserAgent;

    my $ua = LWP::UserAgent->new();
    my $req = POST 'L<http://www.perl.com/cgi-bin/cpan_mod'>,
                   [ module => 'DB_File', readme => 1 ];
    my $content = $ua->request($req)->as_string;

web上で %-encodings をデコードしたり生成したりするには?¶

ほとんどの場合、web フレームワークでこれを行う必要はないはずです; リクエストを作ったときには、LWP やその他のモジュールが代わりにこれらを 扱います。

自分で文字列をエンコードするには、URI::Escape モジュールを使ってください。 uri_escape 関数はエスケープされた文字列を返します:

    my $original = "Colon : Hash # Percent %";

    my $escaped = uri_escape( $original );

    print "$escaped\n"; # 'Colon%20%3A%20Hash%20%23%20Percent%20%25'

文字列をデコードするには、uri_unescape 関数を使います:

    my $unescaped = uri_unescape( $escaped );

    print $unescaped; # back to original

URI 全体をエンコードするのではなく、それぞれの要素を別々にエスケープして それから互いに結合する必要があることを忘れないでください。

別のページにリダイレクトするには?¶

ほとんどの Perl Web フレームワークはこれを行う機構があります; Catalyst フレームワークを使っているなら以下のようになります:

    $c->res->redirect($url);
    $c->detach();

(ほとんどのフレームワークが使っている) Plack を使っていて、 Apache からの移動や常にリダイレクトしたい URL があるなら、 Plack::Middleware::Rewrite は見る価値があるでしょう。

私の web ぺージでパスワードを入力するには?¶

使っている web フレームワークが認証システムを持っているか、そしてそれが 目的に合致しているかを調べてください。

あるいは、Plack::Middleware::Auth::Basic またはその他の Plack 認証 オプションの一つを 見てください。

私の CGI スクリプトに悪影響をもたらすようなものを、ユーザーがフォームに入力できないようにするには?¶

(brian d foy によって寄贈されました)

人々がスクリプトに悪いデータを送るのを防ぐことは出来ません。 例えクライアント側でチェックをしたとしても、それを無効にしたり 完全に回避したりできます。 例えば、LWP のようなモジュールを使って web サイトに 投稿するかもしれません。 SQL インジェクションや同様の種類の攻撃を行うようなデータを防ぎたいのなら (そしておそらくそうしたいでしょう)、プログラムに入力される どんなデータも信用しないようにする必要があります。

perlsec 文書にはデータセキュリティに関する一般的な助言があります。 DBI モジュールを使っているなら、データを埋めるのにプレースホルダを 使ってください。 system や exec で外部プログラムを実行しているなら、リスト形式を 使ってください。 その他、ここに書ききれないほどの注意するべき多くの事前注意があり、 そのほとんどは、使おうとしていないデータは使わないという分野に当てはまります。 誰も信用しないでください。

メールのヘッダーを解析するには?¶

Email::MIME モジュールを使ってください。 これはよくテストされていて、現実世界で見ることになるあらゆる狂気 (コメント畳み込み空白、エンコーディング、コメントなど)に対応しています。

  use Email::MIME;

  my $message = Email::MIME->new($rfc2822);
  my $subject = $message->header('Subject');
  my $from    = $message->header('From');

既に何らかの他の種類のメールオブジェクトがあるなら、それを Email::Abstract に渡して、それから Email::MIME オブジェクトを 得るために cast メソッドを使うことを考慮してください:

  my $mail_message_object = read_message();
  my $abstract = Email::Abstract->new($mail_message_object);
  my $email_mime_object = $abstract->cast('Email::MIME');

メールアドレスが正しいかチェックするには?¶

(一部は Aaron Sherman によって寄贈されました)

これは見た目ほど単純な質問ではありません。 これは二つの部分からなります:

a) メールアドレスが正しい形式かを検証するには?

b) メールアドレスが正当な受信者を対象としているかを検証するには?

そのアドレスにメールを送ってそれが届いたかどうかを確認しなければ 完全にパート b に答えられませんが、Email::Valid か RFC::RFC822::Address のモジュールは、リアルタイムでできる限りの ことに対してパート a とパート b の両方を行います。

私たちができる最善のアドバイスは、個人のメールアドレスをチェックするのに パスワードを変更するときと同じようにユーザーにアドレスを 二回入力させるというものです。 これによって通常は打ち間違いを防ぐことができます。 二回の入力がマッチしたなら、個人的な内容のメッセージをメールとして そのアドレスへ送ります。 もしメッセージが返ってきて、それがあなたの指示に従っているなら、 それが実際のものであると十分に仮定できます。

より偽造のやりにくい別のやり方に、チェックに対象者に対して PIN (Personal ID Number) を与えるというものがあります。 後の処理のためにアドレスと PIN (ランダムであることが望ましい)を 記録しておくのです。 あなたがメールを送るときに、PIN が含まれたあなたのサイトへのリンクを 含めてください。 メールがバウンスしたなら、不正であることが分かります。 リンクがクリックされなければ、アドレスが偽造されたか、(メッセージが 届いたとして) 最後まで行うことが重要ではなかったのでそれについて 気にする必要はないと言うことです。

MIME/BASE64 文字列のデコードを行うには?¶

MIME::Base64 パッケージはこの問題と、 MIME/QP エンコーディングを取り扱います。 BASE64 のデコードは以下のように単純です:

    use MIME::Base64;
    my $decoded = decode_base64($encoded);

Email::MIME モジュールは BASE64 でエンコードされたメールのメッセージ部分を 透過的にデコードできるので、開発者はそれについて気にする必要はありません。

あるユーザーのメールアドレスを知るには?¶

その人に聞いてください。 多くのメールプロバイダが利用可能なので、ローカルシステムがユーザーの メールアドレスを決定する方法はまずありません。

例外は、組織に固有のメール (例えば [email protected]) で、ポリシーを プログラムにコード化できる場合です。 この場合、以下のように $ENV{USER}, $ENV{LOGNAME} およびスカラコンテキストで and getpwuid($<) を 見ることができます:

  my $user_name = getpwuid($<)

しかし、ポリシーがそうなっていない限り、これが正しいかどうかに関して 仮定することはやはりできません。 本当に最良なのはユーザーに聞くことです。

メールを送るには?¶

以下のように、Email::MIME と Email::Sender::Simple モジュールを 使ってください:

  # first, create your message
  my $message = Email::MIME->create(
    header_str => [
      From    => '[email protected]',
      To      => '[email protected]',
      Subject => 'Happy birthday!',
    ],
    attributes => {
      encoding => 'quoted-printable',
      charset  => 'utf-8',
    },
    body_str => "Happy birthday to you!\n",
  );

  use Email::Sender::Simple qw(sendmail);
  sendmail($message);

デフォルトでは、Email::Sender::Simple は、$PATH にあれば `sendmail` を 最初に試します。 これは一般的に間違いです。 メールを送るのに使うリモートのメールサーバがある場合、 Transport クラスの一つを調査することを考慮してください。 これを書いている時点では、利用可能な転送層は以下のようなものです:

Email::Sender::Transport::Sendmail

This is the default. If you can use the mail(1) or mailx(1) program to send mail from the machine where your code runs, you should be able to use this.

これはデフォルトです。 コードを実行しているマシンからメールを送るのに mail(1) や mailx(1) が 使えるなら、これが使えるはずです。

Email::Sender::Transport::SMTP

This transport contacts a remote SMTP server over TCP. It optionally uses SSL and can authenticate to the server via SASL.

この転送層は TCP を使ってリモート SMTP サーバに接続します。 オプションとして SSL を使って、SASL 経由でサーバに認証できます。

Email::Sender::Transport::SMTP::TLS

This is like the SMTP transport, but uses TLS security. You can authenticate with this module as well, using any mechanisms your server supports after STARTTLS.

これは SMTP 転送と似ていますが、TLS セキュリティを使います。 このモジュールも、STARTTLS の後サーバが対応している任意の機構を使って 認証できます。

使用する転送層を Email::Sender::Simple に教えるのは簡単です:

  sendmail(
    $message,
    {
      transport => $email_sender_transport_object,
    }
  );

メールメッセージに添付するためにどうやって MIME を使えばいいですか?¶

Email::MIME は直接マルチパートメッセージに対応しています。 Email::MIME 自身はパートで、その他の Email::MIME オブジェクトに 添付できます。 対応している全てのメソッドとその使い方の例を含む、さらなる情報については Email::MIME 文書を参照してください。

メールを読み出すには?¶

以下のように、Email::Folder モジュールを使ってください:

  use Email::Folder;

  my $folder = Email::Folder->new('/path/to/email/folder');
  while(my $message = $folder->next_message) {
    # next_message returns Email::Simple objects, but we want
    # Email::MIME objects as they're more robust
    my $mime = Email::MIME->new($message->as_string);
  }

様々なメールボックスの種類に対応するための異なったクラスが Email::Folder 名前空間にあります。 これらのモジュールは一般的に 読み込み にのみ対応していて書き込みには 対応していないことに注意してください。

私のホスト名/ドメイン名/IP アドレスを見つけるには?¶

(brian d foy によって寄贈されました)

Perl 5.7.3 から標準ライブラリの一部である Net::Domain モジュールを使うと、 完全修飾ドメイン名 (FQDN)、ホスト名、ドメイン名が得られます。

    use Net::Domain qw(hostname hostfqdn hostdomain);

    my $host = hostfqdn();

標準ライブラリの一部である Sys::Hostname モジュールでもホスト名を 得られます。

    use Sys::Hostname;

    $host = hostname();

Sys::Hostname::Long モジュールは異なる手法をとり、完全修飾ホスト名を 返すためにさらに多くのことを試みます:

  use Sys::Hostname::Long 'hostname_long';

  my $hostname = hostname_long();

IP アドレスを得るには、名前から数値に変換するために gethostbyname 組み込み関数が使えます。 数値を、ほとんどの人が想定しているピリオド付きの形 (a.b.c.d) に変換するには、 標準配布されている Socket モジュールの inet_ntoa 関数を使います。

    use Socket;

    my $address = inet_ntoa(
        scalar gethostbyname( $host || 'localhost' )
    );

(S)FTP ファイルをダウンロード/アップロードするには?¶

Net::FTP と Net::SFTP で FTP および SFTP (Secure FTP) サーバと 相互作用できるようになります。

Perl で RPC を行うには?¶

RFC モジュール ( https://metacpan.org/search?q=RPC ) の一つを使いましょう。

AUTHOR AND COPYRIGHT¶

Copyright (c) 1997-2010 Tom Christiansen, Nathan Torkington, and other authors as noted. All rights reserved.

This documentation is free; you can redistribute it and/or modify it under the same terms as Perl itself.

Irrespective of its distribution, all code examples in this file are hereby placed into the public domain. You are permitted and encouraged to use this code in your own programs for fun or for profit as you see fit. A simple comment in the code giving credit would be courteous but is not required.