名前¶

perlvar - Perl で定義済みの変数

説明¶

変数名の文法¶

Perl の変数名は様々な形があります。 通常、変数名は英文字か下線で始まらなければならず、 任意の長さ(内部制限の 251 文字まで)を取ることができ、 英文字、数字、下線、特別な文字列である :: と ' を含むことができます。 この場合、最後の :: または ' の前は パッケージ限定子 として扱われます。 perlmod を参照して下さい。

Perl の変数は、数字の列または一文字の句読点かコントロール文字の 場合もあります。 これらの名前は全て Perl によって特別な用途のために予約されています。 例えば、全て数字の名前は正規表現マッチの後の後方参照のデータを 保持するために用いられます。 Perl には一文字のコントロール文字の名前のための特別な文法があります。 ^X(キャレット X)は control-X キャラクタを意味します。 例えば、$^W(ドル記号 キャレット W)は control-W 一文字の 名前をもつスカラ変数です。 これはプログラム中にリテラルな control-W をタイプするより 良いです。

Perl 5.6 から、制御文字(もっと言えばキャレット)で始まる、英数字からなる 文字列の変数名も使えます。 これらの変数は ${^Foo} の形で書かれなければなりません。 括弧は必須です。 ${^Foo} はコントロール-F の後に二つ o が続く名前を持つ スカラ変数です。 これらの変数は Perl によって特別な用途のために予約されていますが、 ^_ (コントロール-下線またはキャレット-下線)で始まるものは例外です。 ^_ で始まるコントロール文字名は Perl の将来のバージョンで 特別な意味を持つことはありません。 従ってこれらの名前はプログラム中で安全に使用できます。 但し、$^_ そのものは 予約されます。

数字、コントロール文字、句読点で始まる Perl の識別子は package 宣言の効果から逃れて、常に main パッケージにあるものとして 扱われます。さらに以下のものも逃れます:

        ENV      STDIN
        INC      STDOUT
        ARGV     STDERR
        ARGVOUT
        SIG

特に、新しい特別な ${^_XYZ} 変数はスコープ内の package 宣言に関わらず 常に main パッケージとして扱われます。

特殊変数¶

以下の名前は Perl では特別な意味を持ちます。 記号的な名前の多くは記憶法があるか、シェルでの類推が可能です。 それでも長い名前を使用したい場合には

        use English;

とプログラムの最初に書いてください。 これは、すべての短い名前の別名として、 カレントパッケージで長い名前を付けるものです。 awk から持ってきた中間的な名前を持っているものもあります。 パフォーマンスの影響を避けるために、もし $PREMATCH, $MATCH, $POSTMATCH が必要ないなら、これらなしで English モジュールを使うのが 最善です:

    use English '-no_match_vars';

先に進む前に、変数のソート順に注意してください。 一般的に、変数を大文字小文字を無視して、ほとんど辞書順に並んでいます (${^UNICODE} や $^T 先頭についている { や ^ は無視します)が、 $_ と @_ は先頭に来ます。 同じ識別子を持つ変数については、スカラ、配列、ハッシュ、裸の単語の順に 並べています。

一般変数¶

$ARG

$_

The default input and pattern-searching space. The following pairs are equivalent:

デフォルトの入力とパターン検索のスペース。 以下の 2つは同値です:

        while (<>) {...}    # equivalent only in while!
        while (defined($_ = <>)) {...}

        /^Subject:/
        $_ =~ /^Subject:/

        tr/a-z/A-Z/
        $_ =~ tr/a-z/A-Z/

        chomp
        chomp($_)

Here are the places where Perl will assume $_ even if you don't use it:

あなたが使いたくなくても Perl が $_ を仮定する場合がいくつかあります:

• The following functions use $_ as a default argument:

  以下の関数は $_ をデフォルト引数として使います:

  abs, alarm, chomp, chop, chr, chroot, cos, defined, eval, exp, glob, hex, int, lc, lcfirst, length, log, lstat, mkdir, oct, ord, pos, print, quotemeta, readlink, readpipe, ref, require, reverse (in scalar context only), rmdir, sin, split (on its second argument), sqrt, stat, study, uc, ucfirst, unlink, unpack.

  abs, alarm, chomp, chop, chr, chroot, cos, defined, eval, exp, glob, hex, int, lc, lcfirst, length, log, lstat, mkdir, oct, ord, pos, print, quotemeta, readlink, readpipe, ref, require, reverse (スカラコンテキストのみ), rmdir, sin, split (の 2 番目の引数), sqrt, stat, study, uc, ucfirst, unlink, unpack.

• All file tests (-f, -d) except for -t, which defaults to STDIN. See "-X" in perlfunc

  デフォルトが STDIN である -t を除く全てのファイルテスト(-f, -d) 。 "-X" in perlfunc を参照してください。

• The pattern matching operations m//, s/// and tr/// (aka y///) when used without an =~ operator.

  =~ 演算子なしで用いられたパターンマッチ演算 m//, s///, tr/// (またの名を y///)。

• The default iterator variable in a foreach loop if no other variable is supplied.

  foreach ループでの他の変数が補われなかった場合のデフォルトの 繰り返し変数。

• The implicit iterator variable in the grep() and map() functions.

  grep() 関数と map() 関数の暗黙の繰り返し変数。

• The implicit variable of given().

  given() の暗黙の変数。

• The default place to put an input record when a <FH> operation's result is tested by itself as the sole criterion of a while test. Outside a while test, this will not happen.

  <FH> が単独で while テストでテストされた場合の 結果を入れるデフォルトの場所。 while テスト以外ではこれは起こりません。

As $_ is a global variable, this may lead in some cases to unwanted side-effects. As of perl 5.9.1, you can now use a lexical version of $_ by declaring it in a file or in a block with my. Moreover, declaring our $_ restores the global $_ in the current scope.

$_ はグローバル変数なので、望まないような副作用を引き起こす場合があります。 perl 5.9.1 から、ファイルやブロックで my で宣言することで、 レキシカル版の $_ が使えます。 さらに、our $_ という宣言は現在のスコープでグローバルな $_ を 再構築します。

Mnemonic: underline is understood in certain operations.

記憶法: 下線はある操作を覚えるためのもの。

@ARG

@_

Within a subroutine the array @_ contains the parameters passed to that subroutine. Inside a subroutine, @_ is the default array for the array operators push, pop, shift, and unshift.

サブルーチンに入るときには、配列 @_ はサブルーチンに渡された パラメータです。 サブルーチンの内部では、@_ は配列演算子 push, pop, shift, unshift のデフォルト配列です。

See perlsub.

perlsub を参照して下さい。

$LIST_SEPARATOR

$"

When an array or an array slice is interpolated into a double-quoted string or a similar context such as /.../, its elements are separated by this value. Default is a space. For example, this:

配列や配列スライスがダブルクォートされた文字列あるいは /.../ のような 同様のコンテキスト展開されたとき、その要素はこの値で分割されます。 デフォルトは空白です。 例えば、以下のものは:

        print "The array is: @array\n";

is equivalent to this:

以下と等価です:

        print "The array is: " . join($", @array) . "\n";

Mnemonic: works in double-quoted context.

記憶法: ダブルクォートされた内容に対して動作します。

$PROCESS_ID

$PID

$$

The process number of the Perl running this script. You should consider this variable read-only, although it will be altered across fork() calls.

スクリプトを実行している Perl のプロセス番号です。 この変数は read-only と考えるべきですが、 fork() 呼び出しによって値は変わります。

Note for Linux users: on Linux, the C functions getpid() and getppid() return different values from different threads. In order to be portable, this behavior is not reflected by $$, whose value remains consistent across threads. If you want to call the underlying getpid(), you may use the CPAN module Linux::Pid.

Linux ユーザーへの注意: Linux では、C 関数 getpid() と getppid() は スレッドが異なると異なった値を返します。 移植性のために、この振る舞いは $$ には反映されず、この値はスレッド間で 一貫しています。 もし内在する getpid() を呼び出したい場合は、CPAN モジュール Linux::Pid が使えます。

Mnemonic: same as shells.

記憶法: シェルと同じ。

$REAL_GROUP_ID

$GID

$(

The real gid of this process. If you are on a machine that supports membership in multiple groups simultaneously, gives a space separated list of groups you are in. The first number is the one returned by getgid(), and the subsequent ones by getgroups(), one of which may be the same as the first number.

本プロセスの実 gid を示します。 同時に複数のグループに所属できるマシンでは、所属するグループをスペースで 区切ったリストが得られます。 最初の数値は、getgid() で返されるものです。 その後に getgroups() が返す値が続き、その中の 1 つは、 最初の値と同じかもしれません。

However, a value assigned to $( must be a single number used to set the real gid. So the value given by $( should not be assigned back to $( without being forced numeric, such as by adding zero. Note that this is different to the effective gid ($)) which does take a list.

しかし、$( に代入された値は実際の gid に設定された値の 一つでなければなりません。 従って、 $( で与えられた値はゼロを足すことによって 数値化することなく $( に書き戻すべきではありません。 これはリストが得られる実行 GID ($)) とは違うことに注意してください。

You can change both the real gid and the effective gid at the same time by using POSIX::setgid(). Changes to $( require a check to $! to detect any possible errors after an attempted change.

POSIX::setgid() を使って、実 GID と実効 GID の両方を同時に変更できます。 $( を変更した場合は、変更しようとしたときに起こりうるエラーを検出するために $! をチェックする必要があります。

Mnemonic: parentheses are used to group things. The real gid is the group you left, if you're running setgid.

記憶法: 括弧は、グループ化に使われます。 setgid で実行中であれば、実 gid は left した、つまり離れたグループです。

$EFFECTIVE_GROUP_ID

$EGID

$)

The effective gid of this process. If you are on a machine that supports membership in multiple groups simultaneously, gives a space separated list of groups you are in. The first number is the one returned by getegid(), and the subsequent ones by getgroups(), one of which may be the same as the first number.

本プロセスの実効 gid を示します。 同時に複数のグループに所属できるマシンでは、 所属するグループをスペースで区切ったリストが得られます。 最初の数値は、getegid() で返されるものです。 その後に getgroups() が返す値が続き、その中の 1 つは、 最初の値と同じかもしれません。

Similarly, a value assigned to $) must also be a space-separated list of numbers. The first number sets the effective gid, and the rest (if any) are passed to setgroups(). To get the effect of an empty list for setgroups(), just repeat the new effective gid; that is, to force an effective gid of 5 and an effectively empty setgroups() list, say $) = "5 5" .

同様に、$) へ代入する値はスペースで区切られた数値の リストでなければなりません。 最初の数値は実効 gid を設定し、残りの数値は(もしあれば) setgroups() に 渡されます。 setgroups() に空リストを渡したい場合は、単に新しい実効 gid を 繰り返してください。 つまり、実効 gid を 5 にして、setgroups() に空リストを渡したい場合は、 $) = "5 5" としてください。

You can change both the effective gid and the real gid at the same time by using POSIX::setgid() (use only a single numeric argument). Changes to $) require a check to $! to detect any possible errors after an attempted change.

POSIX::setgid() を使って、実効 GID と実 GID を同時に変更できます。 (1 つの数値引数だけが使えます)。 $) を変更した場合は、変更時に起こりうるエラーを検出するために $! の チェックが必要です。

$<, $>, $( and $) can be set only on machines that support the corresponding set[re][ug]id() routine. $( and $) can be swapped only on machines supporting setregid().

$<, $>, $(, $) は、実行するマシンで、 対応する set[re][ug]id() ルーティンがサポートされているときにのみ 設定可能です。 $( と $) の交換は、 setregid() がサポートされているマシンでのみ可能です。

Mnemonic: parentheses are used to group things. The effective gid is the group that's right for you, if you're running setgid.

記憶法: 括弧は、グループ化に使われます。 setgid で実行中であれば、実効 gid は right な、つまり正しいグループです。

$PROGRAM_NAME

$0

Contains the name of the program being executed.

実行されているプログラムの名前を示します。

On some (but not all) operating systems assigning to $0 modifies the argument area that the ps program sees. On some platforms you may have to use special ps options or a different ps to see the changes. Modifying the $0 is more useful as a way of indicating the current program state than it is for hiding the program you're running.

一部の(しかし全てではありません)オペレーティングシステムでは $0 に代入を行なうことで ps プログラムが見る引数エリアを修正します。 プラットフォームによっては、この変更を見るために 特殊な ps オプションや、 他の ps を使う必要があるものもあります。 $0 の修正は、実行しているプログラムを隠すよりは、 実行中のプログラムの状態を表示するときに、使うとよいでしょう。

Note that there are platform-specific limitations on the maximum length of $0. In the most extreme case it may be limited to the space occupied by the original $0.

$0 の最大長にはプラットフォーム固有の制限があることに注意してください。 最も極端な場合では、元の $0 で占められているサイズに制限されます。

In some platforms there may be arbitrary amount of padding, for example space characters, after the modified name as shown by ps. In some platforms this padding may extend all the way to the original length of the argument area, no matter what you do (this is the case for example with Linux 2.2).

プラットフォームによっては、任意の量のパッディングがある場合があります; 例えば、ps で見られる修正された名前の後の空白文字です。 プラットフォームによっては、このパッディングは、あなたが何をしたかに 関わらず、元の引数のエリア全体に拡張されるものもあります (例えば、これは Linux 2.2 の場合です)。

Note for BSD users: setting $0 does not completely remove "perl" from the ps(1) output. For example, setting $0 to "foobar" may result in "perl: foobar (perl)" (whether both the "perl: " prefix and the " (perl)" suffix are shown depends on your exact BSD variant and version). This is an operating system feature, Perl cannot help it.

BSD ユーザーへの注意: $0 に値をセットしても、ps(1) の出力から 完全に "perl" の文字列は取り除かれません。 例えば、$0 に "foobar" と設定すると、"perl: foobar (perl)" という 結果になります ("perl: " 接頭辞と" (perl)" 接尾辞が表示されるかどうかは 、正確な BSD の種類とバージョンに依存します)。 これはオペレーティングシステムの機能で、Perl は何もできません。

In multithreaded scripts Perl coordinates the threads so that any thread may modify its copy of the $0 and the change becomes visible to ps(1) (assuming the operating system plays along). Note that the view of $0 the other threads have will not change since they have their own copies of it.

マルチスレッドスクリプトでは、どのスレッドも自身の $0 のコピーを 変更できて、その変更が(OS が対応しているとして) ps(1) で見えるように、 Perl がスレッドを調整します。 他のスレッドが持っている $0 の見え方は(各自が自身のコピーを 持っているので)変わらないことに注意してください。

If the program has been given to perl via the switches -e or -E, $0 will contain the string "-e".

プログラムが perl に -e または -E オプション経由で与えられた場合、 $0 には文字列 "-e" を含みます。

On Linux as of perl 5.14 the legacy process name will be set with prctl(2), in addition to altering the POSIX name via argv[0] as perl has done since version 4.000. Now system utilities that read the legacy process name such as ps, top and killall will recognize the name you set when assigning to $0. The string you supply will be cut off at 16 bytes, this is a limitation imposed by Linux.

Linux では perl 5.14 以降、perl がバージョン 4.000 以降行っていた argv[0] 経由での POSIX 名の置き換えに加えて、 レガシープロセス名は prctl(2) で設定されます。 今では ps, top, killall のようにレガシープロセス名を読むユーティリティは $0 に代入することに設定される名前を認識します。 指定した文字列は 16 バイトに切り詰められます; これは Linux による 制限です。

Mnemonic: same as sh and ksh.

記憶法: sh や ksh と同じ。

$SUBSCRIPT_SEPARATOR

$SUBSEP

$;

The subscript separator for multidimensional array emulation. If you refer to a hash element as

多次元配列のエミュレートのための添え字の区切文字。 ハッシュの要素を

        $foo{$a,$b,$c}

it really means

のようにして参照すると、実際には

        $foo{join($;, $a, $b, $c)}

But don't put

という意味になります。 しかし、

        @foo{$a,$b,$c}  # a slice--note the @

which means

としてはいけません。 これは以下の意味になります。

        ($foo{$a},$foo{$b},$foo{$c})

Default is "\034", the same as SUBSEP in awk. If your keys contain binary data there might not be any safe value for $;.

デフォルトは "\034" で、awk の SUBSEP と同じです。 使おうとしている key の値がバイナリのデータを含むならば、 $; に設定する安全な値などはないことになります。

Consider using "real" multidimensional arrays as described in perllol.

perllol で記述している「本物の」多次元配列を使うようにしてください。

Mnemonic: comma (the syntactic subscript separator) is a semi-semicolon.

記憶法: コンマ (構文上の添え字区切り文字) は セミ−セミコロンなのです。

$REAL_USER_ID

$UID

$<

The real uid of this process. You can change both the real uid and the effective uid at the same time by using POSIX::setuid(). Since changes to $< require a system call, check $! after a change attempt to detect any possible errors.

本プロセスの実 uid を示します。 POSIX::setuid() を使って、実効 UID と実 UID を同時に変更できます。 $< の変更にはシステムコールが必要なので、起こりうるエラーを 検出するために $! のチェックが必要です。

Mnemonic: it's the uid you came from, if you're running setuid.

記憶法: setuid で実行中であれば、そこ「から」来た uid です。

$EFFECTIVE_USER_ID

$EUID

$>

The effective uid of this process. For example:

本プロセスの実効 uid を示します。 例えば:

        $< = $>;            # set real to effective uid
        ($<,$>) = ($>,$<);  # swap real and effective uids

You can change both the effective uid and the real uid at the same time by using POSIX::setuid(). Changes to $> require a check to $! to detect any possible errors after an attempted change.

POSIX::setuid() を使って、実効 UID と実 UID を同時に変更できます。 $> を変更した場合は、変更時に起こりうるエラーを検出するために $! のチェックが必要です。

$< and $> can be swapped only on machines supporting setreuid().

$< と $> の交換は、setreuid() をサポートしている マシンでのみ可能です。

Mnemonic: it's the uid you went to, if you're running setuid.

記憶法: setuid で実行中であれば、そこ へ 行く uid です。

$a

$b

Special package variables when using sort(), see "sort" in perlfunc. Because of this specialness $a and $b don't need to be declared (using use vars, or our()) even when using the strict 'vars' pragma. Don't lexicalize them with my $a or my $b if you want to be able to use them in the sort() comparison block or function.

sort() を使うときの特殊パッケージ変数です; "sort" in perlfunc を 参照してください。 この特殊性により、$a と $b は、たとえ strict 'vars' プラグマを 使っているときでも (use vars や our() を使って) 宣言する必要が ありません。 これを sort() 比較ブロックや関数で使えるようにしたい場合は、 my $a や my $b としてレキシカル化しないでください。

$COMPILING

$^C

The current value of the flag associated with the -c switch. Mainly of use with -MO=... to allow code to alter its behavior when being compiled, such as for example to AUTOLOAD at compile time rather than normal, deferred loading. Setting $^C = 1 is similar to calling B::minus_c.

-c スイッチに関連付けられた現在の値です。 主に -MO=... と共に用いられ、例えば AUTOLOAD を通常の遅延ロードでは なくコンパイル時に実行するといった、コンパイル時の振る舞いを 変えるために用います。 $^C = 1 に設定することは B::minus_c を呼び出すのと似ています。

This variable was added in Perl 5.6.

この変数は Perl 5.6 で追加されました。

$DEBUGGING

$^D

The current value of the debugging flags. May be read or set. Like its command-line equivalent, you can use numeric or symbolic values, eg $^D = 10 or $^D = "st".

デバッグフラグの現在の値を示します。 読み書き可能です。 コマンドラインによる等価な機能と同様に、数値とシンボル値が使えます (例: $^D = 10 または $^D = "st")。

Mnemonic: value of -D switch.

記憶法: -D スイッチの値。

${^ENCODING}

The object reference to the Encode object that is used to convert the source code to Unicode. Thanks to this variable your Perl script does not have to be written in UTF-8. Default is undef. The direct manipulation of this variable is highly discouraged.

ソースコードを Unicode に変換するために使われる Encode オブジェクトへの オブジェクトリファレンス 。 この変数のおかげで、Perl スクリプトを UTF-8 で書く必要がありません。 デフォルトは undef です。 この変数を直接操作することはとても推奨できません。

This variable was added in Perl 5.8.2.

この変数は Perl 5.8.2 で追加されました。

%ENV

The hash %ENV contains your current environment. Setting a value in ENV changes the environment for any child processes you subsequently fork() off.

ハッシュ %ENV には、その時点の環境変数が設定されています。 ENV に値を設定することで、 以後に fork() した子プロセスの環境変数を変更します。

$SYSTEM_FD_MAX

$^F

The maximum system file descriptor, ordinarily 2. System file descriptors are passed to exec()ed processes, while higher file descriptors are not. Also, during an open(), system file descriptors are preserved even if the open() fails (ordinary file descriptors are closed before the open() is attempted). The close-on-exec status of a file descriptor will be decided according to the value of $^F when the corresponding file, pipe, or socket was opened, not the time of the exec().

システムが使用するファイル記述子の最大値を示し、通常は 2 です。 システムファイル記述子は、exec() されたプロセスに渡されますが、 それ以降のファイル記述子は渡されません。 また、open() の実行中は、システムファイル記述子は、 たとえ open() が失敗しても、保存されます。 (通常のファイル記述子は、open() が実行される前にクローズされます。) ファイル記述子の close-on-exec のステータスは、exec() 時ではなく、 対応するファイル、パイプソケットの open 時の $^F の値によって 決められます。

@F

The array @F contains the fields of each line read in when autosplit mode is turned on. See perlrun for the -a switch. This array is package-specific, and must be declared or given a full package name if not in package main when running under strict 'vars'.

自動 split モードが有効の場合、配列 @F には読み込んだ行のフィールドを 含みます。 -a オプションについては perlrun を参照してください。 この配列はパッケージ固有であり、もし strict 'vars' で実行していて パッケージ main 以外の場合は完全なパッケージ名で定義したり与えたり しなければなりません。

${^GLOBAL_PHASE}

The current phase of the perl interpreter.

perl インタプリタの現在のフェーズ。

Possible values are:

取り得る値は:

CONSTRUCT

The PerlInterpreter* is being constructed via perl_construct. This value is mostly there for completeness and for use via the underlying C variable PL_phase. It's not really possible for Perl code to be executed unless construction of the interpreter is finished.

PerlInterpreter* は perl_construct で構築されます。 この変数はほとんど完全性のためと、基礎となっている C 変数 PL_phase 経由での使用のために存在しています。 実際にはインタプリタの構築が完了しない限り Perl コードを 実行することはできません。

START

This is the global compile-time. That includes, basically, every BEGIN block executed directly or indirectly from during the compile-time of the top-level program.

これはコンパイル時にグローバルです。 これは基本的に、直接実行されたり、トップレベルプログラムの コンパイル時の間に間接的に実行される全ての BEGIN です。

This phase is not called "BEGIN" to avoid confusion with BEGIN-blocks, as those are executed during compile-time of any compilation unit, not just the top-level program. A new, localised compile-time entered at run-time, for example by constructs as eval "use SomeModule" are not global interpreter phases, and therefore aren't reflected by ${^GLOBAL_PHASE}.

BEGIN ブロックとの混乱を避けるために、このフェーズの名前は "BEGIN" では ありません; これらは単にトップレベルプログラムではなく、任意のコンパイル ユニットのコンパイル中に実行されます。 例えば eval "use SomeModule" のように、実行時に入った 新しいローカル化されたコンパイル時はグローバルなインタプリタフェーズではなく、 従って ${^GLOBAL_PHASE} に反映されません。

CHECK

Execution of any CHECK blocks.

CHECK ブロックの実行。

INIT

Similar to "CHECK", but for INIT-blocks, not CHECK blocks.

"CHECK" と似ていますが、CHECK ブロックではなく INIT ブロック。

RUN

The main run-time, i.e. the execution of PL_main_root.

メインの実行; つまり PL_main_root の実行。

END

Execution of any END blocks.

END ブロックの実行。

DESTRUCT

Global destruction.

グローバルなデストラクタ。

Also note that there's no value for UNITCHECK-blocks. That's because those are run for each compilation unit individually, and therefore is not a global interpreter phase.

また、UNITCHECK ブロックのための値はないことに注意してください。 なぜなら、これらはコンパイルユニット毎に独立に実行され、従って グローバルなインタプリタフェーズではないからです。

Not every program has to go through each of the possible phases, but transition from one phase to another can only happen in the order described in the above list.

全てのプログラムが可能な全てのフェーズを通らなければならないわけでは ありませんが、あるフェーズから他のフェーズへの移行は上述の 順でのみ起こります。

An example of all of the phases Perl code can see:

Perl コードの全てのフェーズを見る例です:

    BEGIN { print "compile-time: ${^GLOBAL_PHASE}\n" }

    INIT  { print "init-time: ${^GLOBAL_PHASE}\n" }

    CHECK { print "check-time: ${^GLOBAL_PHASE}\n" }

    {
        package Print::Phase;

        sub new {
            my ($class, $time) = @_;
            return bless \$time, $class;
        }

        sub DESTROY {
            my $self = shift;
            print "$$self: ${^GLOBAL_PHASE}\n";
        }
    }

    print "run-time: ${^GLOBAL_PHASE}\n";

    my $runtime = Print::Phase->new(
        "lexical variables are garbage collected before END"
    );

    END   { print "end-time: ${^GLOBAL_PHASE}\n" }

    our $destruct = Print::Phase->new(
        "package variables are garbage collected after END"
    );

This will print out

これは以下のものを出力します:

    compile-time: START
    check-time: CHECK
    init-time: INIT
    run-time: RUN
    lexical variables are garbage collected before END: RUN
    end-time: END
    package variables are garbage collected after END: DESTRUCT

This variable was added in Perl 5.14.0.

この変数は Perl 5.14.0 で追加されました。

$^H

WARNING: This variable is strictly for internal use only. Its availability, behavior, and contents are subject to change without notice.

警告: この変数は厳密に内部使用に限定されます。 その可用性、挙動、内容は告知なく変更される可能性があります。

This variable contains compile-time hints for the Perl interpreter. At the end of compilation of a BLOCK the value of this variable is restored to the value when the interpreter started to compile the BLOCK.

この変数には Perl インタプリタのコンパイル時のヒントが入ります。 BLOCK のコンパイル終了時に、この変数の値は インタプリタが BLOCK のコンパイルを開始した時の値に戻されます。

When perl begins to parse any block construct that provides a lexical scope (e.g., eval body, required file, subroutine body, loop body, or conditional block), the existing value of $^H is saved, but its value is left unchanged. When the compilation of the block is completed, it regains the saved value. Between the points where its value is saved and restored, code that executes within BEGIN blocks is free to change the value of $^H.

Perl がレキシカルスコープを持つブロック構造(eval の中身、required された ファイル、サブルーチンの中身、loop の中身、条件付きブロック)の パーズを開始するとき、現在の $^H の値は保存されますが、値は 変更されません。 ブロックのコンパイルが終わると、保存された値が戻されます。 値の保存と回復の間の地点で、BEGIN ブロックの中で実行されるコードは自由に $^H の値を変更できます。

This behavior provides the semantic of lexical scoping, and is used in, for instance, the use strict pragma.

この振る舞いはレキシカルスコープを持ち、その中で使えます。 例としては use strict があります。

The contents should be an integer; different bits of it are used for different pragmatic flags. Here's an example:

内容は整数であるべきです。 ビット毎に異なるプラグマフラグとして使われます。以下は例です:

        sub add_100 { $^H |= 0x100 }

        sub foo {
                BEGIN { add_100() }
                bar->baz($boon);
        }

Consider what happens during execution of the BEGIN block. At this point the BEGIN block has already been compiled, but the body of foo() is still being compiled. The new value of $^H will therefore be visible only while the body of foo() is being compiled.

BEGIN ブロックの実行中に起こることを考えてみます。 この時点で BEGIN ブロックは既にコンパイルされていますが、 foo() の中身はまだコンパイル中です。 従って $^H の新しい値は foo() の中身がコンパイル中にのみ 見ることが出来ます。

Substitution of BEGIN { add_100() } block with:

BEGIN { add_100() } ブロックを以下のように変更すると:

        BEGIN { require strict; strict->import('vars') }

demonstrates how use strict 'vars' is implemented. Here's a conditional version of the same lexical pragma:

どのように use strict 'vars' が実装されているかがわかります。 以下は同じレキシカルプラグマの条件付き版です:

        BEGIN { require strict; strict->import('vars') if $condition }

This variable was added in Perl 5.003.

この変数は Perl 5.003 で追加されました。

%^H

The %^H hash provides the same scoping semantic as $^H. This makes it useful for implementation of lexically scoped pragmas. See perlpragma.

%^H ハッシュは $^H と同じスコープを持ちます。 これはレキシカルスコープを持つプラグマを実装するのに便利です。 perlpragma を参照してください。

This variable was added in Perl 5.6.

この変数は Perl 5.6 で追加されました。

@INC

The array @INC contains the list of places that the do EXPR, require, or use constructs look for their library files. It initially consists of the arguments to any -I command-line switches, followed by the default Perl library, probably /usr/local/lib/perl, followed by ".", to represent the current directory. ("." will not be appended if taint checks are enabled, either by -T or by -t.) If you need to modify this at runtime, you should use the use lib pragma to get the machine-dependent library properly loaded also:

配列 @INC には、do EXPR, require, use によってライブラリファイルを 探すときに評価する場所のリストが納められています。 初期状態では、コマンドラインスイッチ -I の引数と デフォルトの Perl ライブラリディレクトリ (おそらく /usr/local/lib/perl5) とカレントディレクトリを表わす "." を順につなげたものです。 (-T か -t によって汚染チェックが有効の場合は、"." は追加されません。) 実行時にこれを変更する必要がある場合は、マシン依存のライブラリも正しく 読み込むために use lib を使うべきです:

        use lib '/mypath/libdir/';
        use SomeMod;

You can also insert hooks into the file inclusion system by putting Perl code directly into @INC. Those hooks may be subroutine references, array references or blessed objects. See "require" in perlfunc for details.

Perl のコードを直接 @INC に入れることで、ファイルインクルード機構に フックを挿入できます。 このフックはサブルーチンリファレンス、配列リファレンス、bless された オブジェクトが可能です。 詳細については "require" in perlfunc を参照してください。

%INC

The hash %INC contains entries for each filename included via the do, require, or use operators. The key is the filename you specified (with module names converted to pathnames), and the value is the location of the file found. The require operator uses this hash to determine whether a particular file has already been included.

ハッシュ %INC は、do, require, use 演算子によって インクルードされた、個々のファイル名をエントリとして持っています。 key は指定したファイル名(モジュール名はパス名に変換されます)で、 value は見つかった場所となっています。 require 演算子は、指定されたファイル名が既に インクルードされているかを、このハッシュを使って調べます。

If the file was loaded via a hook (e.g. a subroutine reference, see "require" in perlfunc for a description of these hooks), this hook is by default inserted into %INC in place of a filename. Note, however, that the hook may have set the %INC entry by itself to provide some more specific info.

ファイルがフック(つまりサブルーチンリファレンス; フックに関する 説明については "require" in perlfunc を参照してください)経由で読み込まれた 場合、このフックはデフォルトではファイル名の代わりに %INC に挿入されます。 しかし、フックはさらなる特定の情報を提供するために、自身で %INC エントリを セットするかもしれないことに注意してください。

$INPLACE_EDIT

$^I

The current value of the inplace-edit extension. Use undef to disable inplace editing.

置き換え編集の拡張子の値を示します。 置き換え編集を禁止するためには、undef を設定します。

Mnemonic: value of -i switch.

記憶法: -i スイッチの値。

$^M

By default, running out of memory is an untrappable, fatal error. However, if suitably built, Perl can use the contents of $^M as an emergency memory pool after die()ing. Suppose that your Perl were compiled with -DPERL_EMERGENCY_SBRK and used Perl's malloc. Then

デフォルトでは、メモリ不足はトラップできない致命的エラーとなります。 しかし、もし適切に構築されていれば、Perl は $^M の中身を die() した後の緊急用メモリとして使えます。 Perl が -DPERL_EMERGENCY_SBRK 付きでコンパイルされ、 Perl の malloc を使うと仮定します。そして、

        $^M = 'a' x (1 << 16);

would allocate a 64K buffer for use in an emergency. See the INSTALL file in the Perl distribution for information on how to add custom C compilation flags when compiling perl. To discourage casual use of this advanced feature, there is no English long name for this variable.

とすると緊急用の 64K のバッファを割り当てます。 perl をコンパイルするときに独自の C コンパイルフラグを追加する 方法についての情報は、Perl 配布パッケージに含まれている INSTALL ファイルを参照して下さい。 この拡張機能を気軽に使えないようにするために、 この変数には English の長い名前はありません。

This variable was added in Perl 5.004.

この変数は Perl 5.004 で追加されました。

$OSNAME

$^O

The name of the operating system under which this copy of Perl was built, as determined during the configuration process. For examples see "PLATFORMS" in perlport.

この Perl が構築されたオペレーティングシステムの名前です。 これは設定プロセス中に決定されます。

The value is identical to $Config{'osname'}. See also Config and the -V command-line switch documented in perlrun.

この値は $Config{'osname'} と同じです。 Config と、perlrun で文書化されている -V コマンドラインスイッチも参照して下さい。

In Windows platforms, $^O is not very helpful: since it is always MSWin32, it doesn't tell the difference between 95/98/ME/NT/2000/XP/CE/.NET. Use Win32::GetOSName() or Win32::GetOSVersion() (see Win32 and perlport) to distinguish between the variants.

Windows プラットフォームでは、$^O はあまり役に立ちません: これは常に MSWin32 となり、95/98/ME/NT/2000/XP/CE/.NET の違いを示していないからです。 これらを区別するためには、Win32::GetOSName() や Win32::GetOSVersion() を 使ってください (Win32 と perlport を参照してください)。

This variable was added in Perl 5.003.

この変数は Perl 5.003 で追加されました。

${^OPEN}

An internal variable used by PerlIO. A string in two parts, separated by a \0 byte, the first part describes the input layers, the second part describes the output layers.

PerlIO で使われる内部変数です。 文字列は \0 で分割された二つの部分からなり、前半は入力層を、 後半は出力層を示します。

This variable was added in Perl 5.8.2.

この変数は Perl 5.8.2 で追加されました。

$PERLDB

$^P

The internal variable for debugging support. The meanings of the various bits are subject to change, but currently indicate:

デバッグ機能のための内部変数です。 それぞれのビットの意味は変わるかもしれませんが、 現在のところは以下の通りです:

0x01

Debug subroutine enter/exit.

サブルーチンの出入りをデバッグします。

0x02

Line-by-line debugging. Causes DB::DB() subroutine to be called for each statement executed. Also causes saving source code lines (like 0x400).

行毎にデバッグします。 各行を実行する毎に DB::DB() サブルーチンを呼び出します。 さらに、(0x400 のように) ソースコードを保存します。

0x04

Switch off optimizations.

最適化を行いません。

0x08

Preserve more data for future interactive inspections.

将来の対話的な検査のためにより多くのデータを保存します。

0x10

Keep info about source lines on which a subroutine is defined.

サブルーチンが定義されたソース行に関する情報を保持します。

0x20

Start with single-step on.

シングルステップ実行で開始します。

0x40

Use subroutine address instead of name when reporting.

報告時にサブルーチン名でなくサブルーチンのアドレスを使います。

0x80

Report goto &subroutine as well.

goto &subroutine も同様に報告します。

0x100

Provide informative "file" names for evals based on the place they were compiled.

eval に対して、コンパイルされた位置を元にした「ファイル」名を提供します。

0x200

Provide informative names to anonymous subroutines based on the place they were compiled.

無名サブルーチンに対して、 コンパイルされた位置を基にした参考名を提供します。

0x400

Save source code lines into @{"_<$filename"}.

ソースコードの行数を @{"_<$filename"} に保存します。

Some bits may be relevant at compile-time only, some at run-time only. This is a new mechanism and the details may change. See also perldebguts.

無名サブルーチンに対して、 コンパイルされた位置を基にした参考名を提供します。 perldebguts も参照してください。

%SIG

The hash %SIG contains signal handlers for signals. For example:

ハッシュ %SIG にはシグナルのためのシグナルハンドラが含まれています。 例えば:

        sub handler {   # 1st argument is signal name
                my($sig) = @_;
                print "Caught a SIG$sig--shutting down\n";
                close(LOG);
                exit(0);
                }

        $SIG{'INT'}  = \&handler;
        $SIG{'QUIT'} = \&handler;
        ...
        $SIG{'INT'}  = 'DEFAULT';   # restore default action
        $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT

Using a value of 'IGNORE' usually has the effect of ignoring the signal, except for the CHLD signal. See perlipc for more about this special case.

'IGNORE' という値は通常はシグナルの効果を無視するために使いますが、 CHLD シグナルは例外です。 この特別な場合に関する詳細は perlipc を参照して下さい。

Here are some other examples:

以下にその他の例を示します:

        $SIG{"PIPE"} = "Plumber";   # assumes main::Plumber (not recommended)
        $SIG{"PIPE"} = \&Plumber;   # just fine; assume current Plumber
        $SIG{"PIPE"} = *Plumber;    # somewhat esoteric
        $SIG{"PIPE"} = Plumber();   # oops, what did Plumber() return??

    $SIG{"PIPE"} = "Plumber";   # main::Plumber を仮定します(非推奨)
    $SIG{"PIPE"} = \&Plumber;   # 問題なし; カレントの Plumber を仮定します
    $SIG{"PIPE"} = *Plumber;    # 少々難解
    $SIG{"PIPE"} = Plumber();   # げげ、Plumber() は何を返すの??

Be sure not to use a bareword as the name of a signal handler, lest you inadvertently call it.

裸の単語をシグナルハンドラの名前として使わないようにしてください。 不注意で呼び出すのを避けるためです。

If your system has the sigaction() function then signal handlers are installed using it. This means you get reliable signal handling.

システムに sigaction() 関数がある場合は、シグナルハンドラが インストールされ使われました。 これにより、信頼性のあるシグナルハンドリングが可能になります。

The default delivery policy of signals changed in Perl 5.8.0 from immediate (also known as "unsafe") to deferred, also known as "safe signals". See perlipc for more information.

デフォルトのシグナル配送ポリシーは Perl 5.8.0 に即時("unsafe"としても 知られます)から保留(「安全なシグナル」としても知られます)に変更されました。 さらなる情報については perlipc を参照してください。

Certain internal hooks can be also set using the %SIG hash. The routine indicated by $SIG{__WARN__} is called when a warning message is about to be printed. The warning message is passed as the first argument. The presence of a __WARN__ hook causes the ordinary printing of warnings to STDERR to be suppressed. You can use this to save warnings in a variable, or turn warnings into fatal errors, like this:

ある種の内部フックも %SIG ハッシュを使ってセットされます。 警告メッセージを表示しようとするときに $SIG{__WARN__} で 示されたルーチンが呼び出されます。 警告メッセージは最初の引数として渡されます。 __WARN__ フックがあると、通常の STDERR への警告の出力は行われません。 これを使って、警告メッセージを変数にいれたり、 あるいは以下のようにして警告を致命的エラーに変えたり出来ます:

        local $SIG{__WARN__} = sub { die $_[0] };
        eval $proggie;

As the 'IGNORE' hook is not supported by __WARN__, you can disable warnings using the empty subroutine:

__WARN__ では 'IGNORE' フックには対応していないので、空サブルーチンを 使って警告を無効に出来ます:

        local $SIG{__WARN__} = sub {};

The routine indicated by $SIG{__DIE__} is called when a fatal exception is about to be thrown. The error message is passed as the first argument. When a __DIE__ hook routine returns, the exception processing continues as it would have in the absence of the hook, unless the hook routine itself exits via a goto, a loop exit, or a die(). The __DIE__ handler is explicitly disabled during the call, so that you can die from a __DIE__ handler. Similarly for __WARN__.

$SIG{__DIE__} で示されるルーチンは 致命的な例外がまさに投げられようとするときに呼び出されます。 エラーメッセージは最初の引数として渡されます。 __DIE__ フックから戻ると、 例外処理はフックがなかったかのように再開されますが、 フックルーチン自体が goto、ループ終了、die() によって 終了した場合を除きます。 __DIE__ ハンドラは呼び出し中は明示的に無効になりますので、 __DIE__ ハンドラから die できます。 __WARN__ も同様です。

Due to an implementation glitch, the $SIG{__DIE__} hook is called even inside an eval(). Do not use this to rewrite a pending exception in $@, or as a bizarre substitute for overriding CORE::GLOBAL::die(). This strange action at a distance may be fixed in a future release so that $SIG{__DIE__} is only called if your program is about to exit, as was the original intent. Any other use is deprecated.

実装上の不具合により、$SIG{__DIE__} は eval() の中でも 呼び出されます。これを、$@ の待っている例外を書き換えたり、 CORE::GLOBAL::die() を上書きするのに使わないでください。 この奇妙な行動は将来のリリースで修正される予定なので、 $SIG{__DIE__} は当初の目的通り、 プログラムが終了するときにのみ呼び出されるようになります。 その他の用途は非推奨です。

__DIE__/__WARN__ handlers are very special in one respect: they may be called to report (probable) errors found by the parser. In such a case the parser may be in inconsistent state, so any attempt to evaluate Perl code from such a handler will probably result in a segfault. This means that warnings or errors that result from parsing Perl should be used with extreme caution, like this:

__DIE__ と __WARN__ のハンドラは一つの点で非常に特別です。 パーザによってエラー(であろうもの)を報告するために呼び出されることがある ことです。 このような場合、パーザは不安定な状態になっているかもしれないので、 ハンドラから Perl コードを評価しようとするとセグメンテーションフォールトが 発生するかもしれません。 Perl のパーズ中の警告やエラーは、以下のように非常に注意して扱うべきです;

        require Carp if defined $^S;
        Carp::confess("Something wrong") if defined &Carp::confess;
        die "Something wrong, but could not load Carp to give backtrace...
           To see backtrace try starting Perl with -MCarp switch";

Here the first line will load Carp unless it is the parser who called the handler. The second line will print backtrace and die if Carp was available. The third line will be executed only if Carp was not available.

一行目は、パーザが ハンドラ を呼び出したのでなければ Carp を読み込みます。 二行目 は、Carp が使えるならバックとレースを表示して die します。 三行目は Carp が使えないときにのみ実行されます。

Having to even think about the $^S variable in your exception handlers is simply wrong. $SIG{__DIE__} as currently implemented invites grievous and difficult to track down errors. Avoid it and use an END{} or CORE::GLOBAL::die override instead.

例外ハンドラの中で $^S を使おうなどとは考えてもいけません。 現在の実装の $SIG{__DIE__} は面倒を引き寄せ、エラーの追跡を困難にします。 これの代わりに END{} を使うか、CORE::GLOBAL::die をオーバーライドしてください。

See "die" in perlfunc, "warn" in perlfunc, "eval" in perlfunc, and warnings for additional information.

追加の情報については "die" in perlfunc, "warn" in perlfunc, "eval" in perlfunc, warnings を参照して下さい。

$BASETIME

$^T

The time at which the program began running, in seconds since the epoch (beginning of 1970). The values returned by the -M, -A, and -C filetests are based on this value.

プログラムを実行開始した時刻を、紀元 (1970年の始め) からの秒数で示したものです。 ファイルテスト -M、-A、-C で返される値は、この値に基づいています。

${^TAINT}

Reflects if taint mode is on or off. 1 for on (the program was run with -T), 0 for off, -1 when only taint warnings are enabled (i.e. with -t or -TU).

汚染検査モードのオン・オフを反映します。 1 はオン(プログラムは -T 付きで実行されている)、0 はオフ、-1 は汚染 警告のみが有効になっている(つまり -t か -TU)ことを意味します。

This variable is read-only.

この変数は読み込み専用です。

This variable was added in Perl 5.8.

この変数は Perl 5.8 で追加されました。

${^UNICODE}

Reflects certain Unicode settings of Perl. See perlrun documentation for the -C switch for more information about the possible values.

Perl のいくつかの Unicode 設定を反映します。 設定できる値に関するさらなる情報については perlrun の -C オプションを 参照してください。

This variable is set during Perl startup and is thereafter read-only.

この変数は Perl 起動時に設定され、その後は読み込み専用です。

This variable was added in Perl 5.8.2.

この変数は Perl 5.8.2 で追加されました。

${^UTF8CACHE}

This variable controls the state of the internal UTF-8 offset caching code. 1 for on (the default), 0 for off, -1 to debug the caching code by checking all its results against linear scans, and panicking on any discrepancy.

この変数は内部 UTF-8 オフセットキャッシュコードの状態を制御します。 1 はオン(デフォルト)、0 はオフ、-1 は全ての結果を線形走査と比較して、 矛盾があれば異常終了する、という形でキャッシュコードをデバッグします。

This variable was added in Perl 5.8.9.

この変数は Perl 5.8.9 で追加されました。

${^UTF8LOCALE}

This variable indicates whether a UTF-8 locale was detected by perl at startup. This information is used by perl when it's in adjust-utf8ness-to-locale mode (as when run with the -CL command-line switch); see perlrun for more info on this.

この変数は、起動時に perl によって UTF-8 ロケールが検出されたかどうかを 示します。 この情報は(-CL コマンドラインスイッチで起動されることによって) 「utf8 性をロケールに合わせる」モードのときに perl によって使われます; これに関するさらなる情報は perlrun を参照してください。

This variable was added in Perl 5.8.8.

この変数は Perl 5.8.8 で追加されました。

$PERL_VERSION

$^V

The revision, version, and subversion of the Perl interpreter, represented as a version object.

version オブジェクトとして表現される revision, version, subversion。

This variable first appeared in perl 5.6.0; earlier versions of perl will see an undefined value. Before perl 5.10.0 $^V was represented as a v-string.

この変数は perl 5.6.0 で最初に現れました; それより前のバージョンでは 未定義値となります。 perl 5.10.0 以前では $^V は v-string 形式で表現されます。

$^V can be used to determine whether the Perl interpreter executing a script is in the right range of versions. For example:

$^V はスクリプトを実行している Perl インタプリタのバージョンが 正しい範囲に入っているかを調べるのに使えます。 例:

        warn "Hashes not randomized!\n" if !$^V or $^V lt v5.8.1

To convert $^V into its string representation use sprintf()'s "%vd" conversion:

$^V を文字列表現に変換するには sprintf() の "%vd" 変換を使います:

        printf "version is v%vd\n", $^V;  # Perl's version

See the documentation of use VERSION and require VERSION for a convenient way to fail if the running Perl interpreter is too old.

実行する Perl インタプリタが古すぎる場合に終了する便利な方法に ついては use VERSION と require VERSION のドキュメントを 参照して下さい。

See also $] for an older representation of the Perl version.

Perl バージョンの古い表現については $] も参照して下さい。

This variable was added in Perl 5.6.

この変数は Perl 5.6 で追加されました。

Mnemonic: use ^V for Version Control.

記憶法: ^V をバージョンコントロールに使います。

${^WIN32_SLOPPY_STAT}

If this variable is set to a true value, then stat() on Windows will not try to open the file. This means that the link count cannot be determined and file attributes may be out of date if additional hardlinks to the file exist. On the other hand, not opening the file is considerably faster, especially for files on network drives.

この変数が真の値にセットされると、Windows での stat() はファイルを オープンしようとはしません。 これは、このファイルへの追加のハードリンクが存在する場合、リンクカウントを 決定できませんし、ファイル属性が古いものになるかもしれないことを 意味します。 一方、ファイルを開かないので、(特にファイルがネットワークドライブにある 場合は)大幅に高速です。

This variable could be set in the sitecustomize.pl file to configure the local Perl installation to use "sloppy" stat() by default. See the documentation for -f in perlrun for more information about site customization.

デフォルトで「ずさんな」stat() を使うために、この変数は、ローカルな Perl を設定するための sitecustomize.pl で設定できます。 サイトカスタマイズに関するさらなる情報については perlrun の -f を参照してください。

This variable was added in Perl 5.10.

この変数は Perl 5.10 で追加されました。

$EXECUTABLE_NAME

$^X

The name used to execute the current copy of Perl, from C's argv[0] or (where supported) /proc/self/exe.

Perl バイナリ自身が実行された時の名前を C の argv[0] または (対応していれば) /proc/self/exe から持ってきたものです。

Depending on the host operating system, the value of $^X may be a relative or absolute pathname of the perl program file, or may be the string used to invoke perl but not the pathname of the perl program file. Also, most operating systems permit invoking programs that are not in the PATH environment variable, so there is no guarantee that the value of $^X is in PATH. For VMS, the value may or may not include a version number.

ホスト OS に依存して、$^X の値は perl プログラムファイルの絶対パスかも しれませんし、相対パスかもしれませんし、perl を起動するために使われる 文字列ではありますが perl プログラムファイルのパス名ではないかもしれません。 また、ほとんどの OS は PATH 環境変数にない位置のプログラムを起動することを 許しているので、$^X の値が PATH にある保証はありません。 VMS では、この値はバージョン番号を含む場合も含まない場合もあります。

You usually can use the value of $^X to re-invoke an independent copy of the same perl that is currently running, e.g.,

通常は、現在実行中のものと同じ perl の独立したコピーを再起動するために $^X の値を使えます; つまり:

        @first_run = `$^X -le "print int rand 100 for 1..100"`;

But recall that not all operating systems support forking or capturing of the output of commands, so this complex statement may not be portable.

しかし、全ての OS が fork やコマンドの出力の捕捉に対応しているわけでは ないので、この複雑な文は移植性がないかもしれないことを忘れないでください。

It is not safe to use the value of $^X as a path name of a file, as some operating systems that have a mandatory suffix on executable files do not require use of the suffix when invoking a command. To convert the value of $^X to a path name, use the following statements:

$^X の値をファイルのパス名として使うのは安全ではありません; 実行ファイルに固定の接尾辞があり、コマンドの起動時には接尾辞が不要な OS も あるからです。 $^X の値をパス名に変換するには、以下のコードを使ってください:

        # Build up a set of file names (not command names).
        use Config;
        my $this_perl = $^X;
        if ($^O ne 'VMS') {
                $this_perl .= $Config{_exe}
                  unless $this_perl =~ m/$Config{_exe}$/i;
                }

Because many operating systems permit anyone with read access to the Perl program file to make a copy of it, patch the copy, and then execute the copy, the security-conscious Perl programmer should take care to invoke the installed copy of perl, not the copy referenced by $^X. The following statements accomplish this goal, and produce a pathname that can be invoked as a command or referenced as a file.

多くの OS が Perl のプログラムファイルのコピーを作って、コピーに パッチを当て、それを実行するための読み込み権限を全員に与えているので、 セキュリティ意識のある Perl プログラマは $^X で参照されているコピーではなく、 インストールされている perl を起動するように気をつけるべきです。 以下のコードはこの目的を達成し、コマンドとして起動したりファイルとして 参照するためのパス名を作成します。

        use Config;
        my $secure_perl_path = $Config{perlpath};
        if ($^O ne 'VMS') {
                $secure_perl_path .= $Config{_exe}
                        unless $secure_perl_path =~ m/$Config{_exe}$/i;
                }

正規表現に関する変数¶

正規表現に関連する特殊変数のほとんどは副作用です。 Perl はマッチングに成功したときにこれらの変数を設定するので、変数を 使う前にマッチングの結果をチェックするべきです。 例えば:

        if( /P(A)TT(ER)N/ ) {
                print "I found $1 and $2\n";
                }

これらの変数は特に記さない限り読み込み専用で動的スコープを持ちます。

正規表現変数の動的な特性により、以下のコード片で示されているように、 変数の値はブロック内に制限されます:

        my $outer = 'Wallace and Grommit';
        my $inner = 'Mutt and Jeff';

        my $pattern = qr/(\S+) and (\S+)/;

        sub show_n { print "\$1 is $1; \$2 is $2\n" }

        {
        OUTER:
                show_n() if $outer =~ m/$pattern/;

                INNER: {
                        show_n() if $inner =~ m/$pattern/;
                        }

                show_n();
        }

出力から分かることは、OUTER ブロックの間では $1 と $2 の値は $outer に対するマッチングからのものになります。 INNER ブロックの内側では、$1 と $2 の値は $inner での マッチングからのものになりますが、ブロックの最後までです (つまり、 動的スコープを持ちます)。 INNER ブロックの終了後、$1 と $2 の値は、他のマッチングがなくても $outer に対するマッチングからのものになります:

        $1 is Wallace; $2 is Grommit
        $1 is Mutt; $2 is Jeff
        $1 is Wallace; $2 is Grommit

Perl の実装における不幸な事故により、use English は $`, $&, $' を使うので、プログラム中の全ての 正規表現マッチングにおいてかなりの性能低下を引き起こします; これは use English のスコープ内かどうかに関わりません。 この理由により、ライブラリで use English を使うのは、マッチング変数を 使わずにインポートするのでない限りできるだけ避けてください。

        use English '-no_match_vars'

Devel::NYTProf モジュールと Devel::FindAmpersand モジュールは コードの中でのこれらの問題のあるマッチング変数の仕様を探す助けになります。

Perl 5.10 から、/p マッチングフラグと、 ${^PREMATCH}, ${^MATCH}, ${^POSTMATCH} 変数を代わりに使えて、 パフォーマンスのペナルティだけを受けます。

$<digits> ($1, $2, ...)

Contains the subpattern from the corresponding set of capturing parentheses from the last successful pattern match, not counting patterns matched in nested blocks that have been exited already.

最後に成功したパターンマッチングで対応する括弧のサブパターンにマッチングした 文字列が入っているが、既に抜けてしまったブロックでの パターンマッチングは勘定に入れません。

These variables are read-only and dynamically-scoped.

これらの変数はすべて読み込み専用で、動的なスコープを持ちます。

Mnemonic: like \digits.

(記憶法: \(数字) のようなもの。)

$MATCH

$&

The string matched by the last successful pattern match (not counting any matches hidden within a BLOCK or eval() enclosed by the current BLOCK).

最後に成功したパターンマッチでマッチした文字列 (現在の BLOCK で囲まれた BLOCK や eval() で隠れている部分でのマッチは 勘定に入れません)。

The use of this variable anywhere in a program imposes a considerable performance penalty on all regular expression matches. To avoid this penalty, you can extract the same substring by using "@-". Starting with Perl 5.10, you can use the </p> match flag and the ${^MATCH} variable to do the same thing for particular match operations.

この変数をプログラムのどこかで使うと、プログラム中の全ての正規表現 マッチングにおいてかなりの性能低下を引き起こします。 このペナルティを避けるために、同じ部分文字列を "@-" を使って 抽出できます。 Perl 5.10 から、/p マッチングフラグと ${^MATCH} 変数を 特定のマッチング演算子について同じことをするために使えます。

This variable is read-only and dynamically-scoped.

この変数は読み込み専用で動的スコープを持ちます。

Mnemonic: like & in some editors.

記憶法: あるエディタの & ようなもの。

${^MATCH}

This is similar to $& ($MATCH) except that it does not incur the performance penalty associated with that variable, and is only guaranteed to return a defined value when the pattern was compiled or executed with the /p modifier.

これは $& ($MATCH) と同様ですが、この変数と関連付けられた性能上の ペナルティを被らず、パターンが /p 修飾子付きでコンパイルまたは実行された 場合にのみ定義された値を返すことが保証されます。

This variable was added in Perl 5.10.

この変数は Perl 5.10 で追加されました。

This variable is read-only and dynamically-scoped.

この変数は読み込み専用で動的スコープを持ちます。

$PREMATCH

$`

The string preceding whatever was matched by the last successful pattern match, not counting any matches hidden within a BLOCK or eval enclosed by the current BLOCK.

最後の成功したパターンマッチ (現在のBLOCK で囲まれた BLOCK や eval() に隠れている部分でのマッチは勘定に入れません) で マッチした部分の前の文字列。

The use of this variable anywhere in a program imposes a considerable performance penalty on all regular expression matches. To avoid this penalty, you can extract the same substring by using "@-". Starting with Perl 5.10, you can use the </p> match flag and the ${^PREMATCH} variable to do the same thing for particular match operations.

この変数をプログラムのどこかで使うと、プログラム中の全ての正規表現 マッチングにおいてかなりの性能低下を引き起こします。 このペナルティを避けるために、同じ部分文字列を "@-" を使って 抽出できます。 Perl 5.10 から、/p マッチングフラグと ${^PREMATCH} 変数を 特定のマッチング演算子について同じことをするために使えます。

This variable is read-only and dynamically-scoped.

この変数は読み込み専用で動的スコープを持ちます。

Mnemonic: ` often precedes a quoted string.

記憶法: ` は多くの場合クォートされた文字列の前にある。

${^PREMATCH}

This is similar to $` ($PREMATCH) except that it does not incur the performance penalty associated with that variable, and is only guaranteed to return a defined value when the pattern was compiled or executed with the /p modifier.

これは $` ($PREMATCH) と同様ですが、この変数と関連付けられた性能上の ペナルティを被らず、パターンが /p 修飾子付きでコンパイルまたは実行された 場合にのみ定義された値を返すことが保証されます。

This variable was added in Perl 5.10

この変数は Perl 5.10 で追加されました。

This variable is read-only and dynamically-scoped.

この変数は読み込み専用で動的スコープを持ちます。

$POSTMATCH

$'

The string following whatever was matched by the last successful pattern match (not counting any matches hidden within a BLOCK or eval() enclosed by the current BLOCK). Example:

最後の成功したパターンマッチ (現在のBLOCK で囲まれた BLOCK や eval() に隠れている部分でのマッチは勘定に入れない) で マッチした部分に続く文字列。 例:

        local $_ = 'abcdefghi';
        /def/;
        print "$`:$&:$'\n";     # prints abc:def:ghi

The use of this variable anywhere in a program imposes a considerable performance penalty on all regular expression matches. To avoid this penalty, you can extract the same substring by using "@-". Starting with Perl 5.10, you can use the </p> match flag and the ${^POSTMATCH} variable to do the same thing for particular match operations.

この変数をプログラムのどこかで使うと、プログラム中の全ての正規表現 マッチングにおいてかなりの性能低下を引き起こします。 このペナルティを避けるために、同じ部分文字列を "@-" を使って 抽出できます。 Perl 5.10 から、/p マッチングフラグと ${^POSTMATCH} 変数を 特定のマッチング演算子について同じことをするために使えます。

This variable is read-only and dynamically-scoped.

この変数は読み込み専用で動的スコープを持ちます。

Mnemonic: ' often follows a quoted string.

記憶法: ' は多くの場合クォートされた文字列の後にある。

${^POSTMATCH}

This is similar to $' ($POSTMATCH) except that it does not incur the performance penalty associated with that variable, and is only guaranteed to return a defined value when the pattern was compiled or executed with the /p modifier.

これは $' ($POSTMATCH) と同様ですが、この変数と関連付けられた性能上の ペナルティを被らず、パターンが /p 修飾子付きでコンパイルまたは実行された 場合にのみ定義された値を返すことが保証されます。

This variable was added in Perl 5.10.

この変数は Perl 5.10 で追加されました。

This variable is read-only and dynamically-scoped.

この変数は読み込み専用で動的スコープを持ちます。

$LAST_PAREN_MATCH

$+

The text matched by the last bracket of the last successful search pattern. This is useful if you don't know which one of a set of alternative patterns matched. For example:

最後に検索されたパターンの最後の括弧にマッチした文字列。 これはいくつかの選択肢の中でどれがマッチするのか わからないような場合に使うと便利です。たとえば:

        /Version: (.*)|Revision: (.*)/ && ($rev = $+);

This variable is read-only and dynamically-scoped.

この変数は読み込み専用で動的スコープを持ちます。

Mnemonic: be positive and forward looking.

記憶法: ポジティブで前向き。

$LAST_SUBMATCH_RESULT

$^N

The text matched by the used group most-recently closed (i.e. the group with the rightmost closing parenthesis) of the last successful search pattern.

最近のマッチングに成功した検索パターンのうち、一番最近に閉じられた 使われたグループ(つまり、一番右の閉じかっこのグループ)にマッチングした テキスト。

This is primarily used inside (?{...}) blocks for examining text recently matched. For example, to effectively capture text to a variable (in addition to $1, $2, etc.), replace (...) with

これは主として最近マッチしたテキストを調べるために (?{...}) ブロックの 中で使われます。 例えば、($1, $2 などに加えて) テキストを変数に効率的に捕捉するには、 (...) を以下で置き換えます:

        (?:(...)(?{ $var = $^N }))

By setting and then using $var in this way relieves you from having to worry about exactly which numbered set of parentheses they are.

$var をこの方法で設定してから使うことで、かっこの組の番号について 気にしなくてすむようになります。

This variable was added in Perl 5.8.

この変数は Perl 5.8 で追加されました。

Mnemonic: the (possibly) Nested parenthesis that most recently closed.

記憶法: もっとも最近閉じられた、(おそらく) ネストした (Nested) かっこ。

@LAST_MATCH_END

@+

This array holds the offsets of the ends of the last successful submatches in the currently active dynamic scope. $+[0] is the offset into the string of the end of the entire match. This is the same value as what the pos function returns when called on the variable that was matched against. The nth element of this array holds the offset of the nth submatch, so $+[1] is the offset past where $1 ends, $+[2] the offset past where $2 ends, and so on. You can use $#+ to determine how many subgroups were in the last successful match. See the examples given for the @- variable.

この配列は、現在アクティブな動的スコープで最後に成功した サブマッチの最後へのオフセットを保持します。 $+[0] はマッチ全体の文字列の最後へのオフセットです。 これはマッチした変数に対して pos 関数を呼び出したときの 返り値と同じです。 この配列の n 番目の要素は n 番目のサブマッチのオフセットを 保持していますので、$+[1] は過去の $1 の終わりのオフセット、 $+[2] は $2 のオフセット、という形になります。 $#+ は最後に成功したマッチでいくつサブグループがあるかを 決定するのに使えます。 @- 変数の例を参照して下さい。

This variable was added in Perl 5.6.

この変数は Perl 5.6 で追加されました。

%LAST_PAREN_MATCH

%+

Similar to @+, the %+ hash allows access to the named capture buffers, should they exist, in the last successful match in the currently active dynamic scope.

@+ と同様、%+ ハッシュは、現在アクティブな動的スコープで最後に成功した マッチングの名前付き捕捉バッファ(存在すれば)へのアクセスを可能にします。

For example, $+{foo} is equivalent to $1 after the following match:

例えば、$+{foo} は以下のマッチングの後の $1 と等価です:

        'foo' =~ /(?<foo>foo)/;

The keys of the %+ hash list only the names of buffers that have captured (and that are thus associated to defined values).

%+ ハッシュのキーは捕捉された(従って定義された値と結びついている) バッファの名前のみの一覧です。

The underlying behaviour of %+ is provided by the Tie::Hash::NamedCapture module.

%+ の基礎となる振る舞いは Tie::Hash::NamedCapture モジュールで 提供されています。

Note: %- and %+ are tied views into a common internal hash associated with the last successful regular expression. Therefore mixing iterative access to them via each may have unpredictable results. Likewise, if the last successful match changes, then the results may be surprising.

注意: %- and %+ は最後に成功した正規表現と関連付けられた共通の 内部ハッシュと tie されたビューです。 従って、each 経由で混ざった反復アクセスを行うと、予測不能の結果と なります。 同様に、最後に成功したマッチングを変更すると、結果は驚くべきものとなります。

This variable was added in Perl 5.10.

この変数は Perl 5.10 で追加されました。

This variable is read-only and dynamically-scoped.

この変数は読み込み専用で動的スコープを持ちます。

@LAST_MATCH_START

@-

$-[0] is the offset of the start of the last successful match. $-[n] is the offset of the start of the substring matched by n-th subpattern, or undef if the subpattern did not match.

$-[0] は最後に成功したマッチの先頭のオフセットです。 $-[n] は n 番目のサブパターンにマッチした部分文字列の 先頭のオフセットです。サブパターンがマッチしなかった場合は undef です。

Thus, after a match against $_, $& coincides with substr $_, $-[0], $+[0] - $-[0]. Similarly, $n coincides with substr $_, $-[n], $+[n] - $-[n] if $-[n] is defined, and $+ coincides with substr $_, $-[$#-], $+[$#-] - $-[$#-]. One can use $#- to find the last matched subgroup in the last successful match. Contrast with $#+, the number of subgroups in the regular expression. Compare with @+.

従って $_ のマッチの後、$& は substr $_, $-[0], $+[0] - $-[0] と 一致します。 同様に、$n は、$-[n] が定義されていれば substr $_, $-[n], $+[n] - $-[n] と一致し、 $+ は substr $_, $-[$#-], $+[$#-] - $-[$#-] と一致します。 $#- は直前に成功したマッチで最後のマッチしたサブグループを 探すのに使えます。 正規表現でのサブグループの数である $#+ と対照的です。 @+ と比較してください。

This array holds the offsets of the beginnings of the last successful submatches in the currently active dynamic scope. $-[0] is the offset into the string of the beginning of the entire match. The nth element of this array holds the offset of the nth submatch, so $-[1] is the offset where $1 begins, $-[2] the offset where $2 begins, and so on.

この配列は現在アクティブな動的スコープ内で最後に成功した サブマッチの先頭位置のオフセットを保持します。 $-[0] はマッチ全体の先頭の文字列へのオフセットです。 この配列の n 番目の要素は n 番目のサブマッチへの オフセットを保持しますので、$-[1] は $1 の先頭への オフセット、$-[2] は $2 の先頭へのオフセット、などとなります。

After a match against some variable $var:

ある変数 $var でマッチした後、以下のようになります。

$` is the same as substr($var, 0, $-[0])

($` は substr($var, 0, $-[0]) と同じです。)

$& is the same as substr($var, $-[0], $+[0] - $-[0])

($& は substr($var, $-[0], $+[0] - $-[0]) と同じです。)

$' is the same as substr($var, $+[0])

($' は substr($var, $+[0]) と同じです。)

$1 is the same as substr($var, $-[1], $+[1] - $-[1])

($1 は substr($var, $-[1], $+[1] - $-[1]) と同じです。)

$2 is the same as substr($var, $-[2], $+[2] - $-[2])

($2 は substr($var, $-[2], $+[2] - $-[2]) と同じです。)

$3 is the same as substr($var, $-[3], $+[3] - $-[3])

($3 は substr $var, $-[3], $+[3] - $-[3]) と同じです。)

This variable was added in Perl 5.6.

この変数は Perl 5.6 で追加されました。

%LAST_MATCH_START

%-

Similar to %+, this variable allows access to the named capture groups in the last successful match in the currently active dynamic scope. To each capture group name found in the regular expression, it associates a reference to an array containing the list of values captured by all buffers with that name (should there be several of them), in the order where they appear.

%+ と同様、この変数は現在アクティブな動的スコープで最後に成功した マッチングの名前付き捕捉グループへのアクセスを可能にします。 正規表現中に捕捉グループ名が現れるごとに、その名前のグループ全てで (複数あるでしょう)捕捉されている値のリストを出現順で含む配列への リファレンスと関連付けられます。

Here's an example:

以下に例を示します:

    if ('1234' =~ /(?<A>1)(?<B>2)(?<A>3)(?<B>4)/) {
        foreach my $bufname (sort keys %-) {
            my $ary = $-{$bufname};
            foreach my $idx (0..$#$ary) {
                print "\$-{$bufname}[$idx] : ",
                      (defined($ary->[$idx]) ? "'$ary->[$idx]'" : "undef"),
                      "\n";
            }
        }
    }

would print out:

とすると、以下のものが表示されます:

        $-{A}[0] : '1'
        $-{A}[1] : '3'
        $-{B}[0] : '2'
        $-{B}[1] : '4'

The keys of the %- hash correspond to all buffer names found in the regular expression.

%- ハッシュのキーは正規表現で見つかった全てのバッファ名に対応します。

The behaviour of %- is implemented via the Tie::Hash::NamedCapture module.

%- の振る舞いは Tie::Hash::NamedCapture モジュールを使って 実装されています。

Note: %- and %+ are tied views into a common internal hash associated with the last successful regular expression. Therefore mixing iterative access to them via each may have unpredictable results. Likewise, if the last successful match changes, then the results may be surprising.

注意: %- and %+ は最後に成功した正規表現と関連付けられた共通の 内部ハッシュと tie されたビューです。 従って、each 経由で混ざった反復アクセスを行うと、予測不能の結果と なります。 同様に、最後に成功したマッチングを変更すると、結果は驚くべきものとなります。

This variable was added in Perl 5.10

この変数は Perl 5.10 で追加されました。

This variable is read-only and dynamically-scoped.

この変数は読み込み専用で動的スコープを持ちます。

$LAST_REGEXP_CODE_RESULT

$^R

The result of evaluation of the last successful (?{ code }) regular expression assertion (see perlre). May be written to.

最後に成功した (?{ code }) 正規表現アサートの評価の結果です (perlre を参照して下さい)。おそらくもっと書き足します。

This variable was added in Perl 5.005.

この変数は Perl 5.005 で追加されました。

${^RE_DEBUG_FLAGS}

The current value of the regex debugging flags. Set to 0 for no debug output even when the re 'debug' module is loaded. See re for details.

正規表現デバッグフラグの現在の値です。 0 をセットすると、re 'debug' モジュールが読み込まれていても デバッグ出力を行いません。 詳細については re を参照してください。

This variable was added in Perl 5.10.

この変数は Perl 5.10 で追加されました。

${^RE_TRIE_MAXBUF}

Controls how certain regex optimisations are applied and how much memory they utilize. This value by default is 65536 which corresponds to a 512kB temporary cache. Set this to a higher value to trade memory for speed when matching large alternations. Set it to a lower value if you want the optimisations to be as conservative of memory as possible but still occur, and set it to a negative value to prevent the optimisation and conserve the most memory. Under normal situations this variable should be of no interest to you.

どれくらい正規表現の最適化を行い、どれくらいのメモリを利用するかを 制御します。 デフォルトではこの値は 65536 で、512kB の一時キャッシュに相当します。 この値を大きくすると、大きなものとマッチングするときに速度を重視して 多くのメモリを使います。 もしできるだけ保守的なメモリ消費をするけれども使うこともある、というように 最適化したい場合は小さい値を設定します; 負の値を設定すると最適化は行わず、 最大限メモリを節約します。 通常の状況では、この変数はあなたの興味を引くものではないでしょう。

This variable was added in Perl 5.10.

この変数は Perl 5.10 で追加されました。

ファイルハンドル関連の変数¶

現在選択されているファイルハンドルに依存する変数の場合には、代わりに IO::Handle オブジェクトに関するオブジェクトメソッドを呼び出して 設定することができますが、通常の組み込み変数よりは効率が落ちます。 (以下の要約では HANDLE という語を含んでいます。) まず最初に必ず、

        use IO::Handle;

と書き、その後で以下のように書くか、

        method HANDLE EXPR

もしくはより安全に以下のように書きます:

        HANDLE->method(EXPR)

それぞれのメソッドは、IO::Handle 属性の昔の値を返します。 メソッドはそれぞれ EXPR をとることができ、指定した場合には、 問題の IO::Handle 属性の新しい値を指定することになります。 指定しない場合には、多くのメソッドでは現在の値に対して何もしませんが、 autoflush() では 1 を指定されたものとします。

IO::Handle クラスを読み込むのはコストの高い操作なので、 通常の組み込み変数の使い方を覚えるべきです。

これらの変数のいくつかは「読み込み専用」と考えられます。 つまり、もしこの変数に対して直接またはリファレンスを通して間接に 代入しようとすると、、実行時エラーが発生します。

この文書に記述されているほとんどの特殊変数のデフォルト値を変更するときには とても慎重になるべきです。 ほとんどの場合、これらの変数を変更する前にこれらをローカル化したいでしょう; さもなければ、あなたが変更した特殊変数のデフォルト値に依存している その他のモジュールにも影響を与えるかもしれないからです。 これはファイル全体を一度に読み込む正しい方法の一つです:

        open my $fh, "<", "foo" or die $!;
        local $/; # enable localized slurp mode
        my $content = <$fh>;
        close $fh;

しかし以下のコードは完全に悪いものです:

        open my $fh, "<", "foo" or die $!;
        undef $/; # enable slurp mode
        my $content = <$fh>;
        close $fh;

なぜなら、その他のモジュールでは、デフォルトの「行モード」でファイルを 読もうとするかも知れませんが、もし単に前述のコードを実行すると、 $/ のグローバルな値が、同じ Perl インタプリタ内で実行される その他のコードに対しても変更されるからです。

通常、変数をローカル化するとき、この変更ができるだけ最短のスコープに 影響を与えることを確実にしたいでしょう。 従って、既に小さい {} ブロックの内側であるのでない限り、それを 自身で作るべきです。 例えば:

        my $content = '';
        open my $fh, "<", "foo" or die $!;
        {
                local $/;
                $content = <$fh>;
        }
        close $fh;

以下はどのように自分のコードが壊れるかの例です:

        for ( 1..3 ){
                $\ = "\r\n";
                nasty_break();
                print "$_";
        }

        sub nasty_break {
        $\ = "\f";
        # do something with $_
        }

おそらくこのコードは以下のように表示されることを期待しています:

    "1\r\n2\r\n3\r\n"

しかし、以下のようになります:

    "1\f2\f3\f"

なぜでしょう? nasty_break() は $_ をローカル化する前に変更するからです。 nasty_break() で設定した値は戻ったときにまだそこにあります。 修正するには、local() を追加して、値が nasty_break() の外に 漏れないようにします:

        local $\ = "\f";

このような短い例では問題に気付くのは簡単ですが、より複雑なコードでは、 もし特殊変数の変更をローカル化していないと問題を探すことになります。

$ARGV

Contains the name of the current file when reading from <> .

<> から読込みを行なっているとき、その時点のファイル名を示します。

@ARGV

The array @ARGV contains the command-line arguments intended for the script. $#ARGV is generally the number of arguments minus one, because $ARGV[0] is the first argument, not the program's command name itself. See $0 for the command name.

配列 @ARGV は、コマンドラインからスクリプトに渡す引数が入れられます。 $ARGV[0] がプログラムのコマンド名自身ではなく、 最初の引数ですから、$#ARGV は一般には、引数の個数 - 1 となります。 コマンド名については、$0 を参照してください。

ARGV

The special filehandle that iterates over command-line filenames in @ARGV. Usually written as the null filehandle in the angle operator <>. Note that currently ARGV only has its magical effect within the <> operator; elsewhere it is just a plain filehandle corresponding to the last file opened by <>. In particular, passing \*ARGV as a parameter to a function that expects a filehandle may not cause your function to automatically read the contents of all the files in @ARGV.

@ARGV にあるコマンドラインで指定されたファイル名に対して反復する 特殊ファイルハンドルです。 通常角かっこ <> の中で空ファイルハンドルとして書かれます。 現在のところ、ARGV は <> 演算子の中でのみ特別な効果があることに 注意してください; その他の場所では、<> で開かれた最後のファイルに 対応する普通のファイルハンドルです。 特に、ファイルハンドルを想定している関数に \*ARGV を引数として渡しても、 関数内で @ARGV にある全てのファイルの内容を自動的に読み込むことには なりません。

ARGVOUT

The special filehandle that points to the currently open output file when doing edit-in-place processing with -i. Useful when you have to do a lot of inserting and don't want to keep modifying $_. See perlrun for the -i switch.

-i を使ってその場修正を行っているときに、現在開いている出力ファイルを 示す特殊ファイルハンドルです。 たくさんの挿入をする必要があるときに $_ を修正し続けたくない場合に 有用です。 -i オプションについては perlrun を参照してください。

Handle->output_field_separator( EXPR )

$OUTPUT_FIELD_SEPARATOR

$OFS

$,

The output field separator for the print operator. If defined, this value is printed between each of print's arguments. Default is undef.

print 演算子のための出力フィールドセパレータ。 定義されると、この値がそれぞれの print の引数の間に表示されます。 デフォルトは undef です。

Mnemonic: what is printed when there is a "," in your print statement.

記憶法: print 文で "," を書いた場所に印字されるもの。

HANDLE->input_line_number( EXPR )

$INPUT_LINE_NUMBER

$NR

$.

Current line number for the last filehandle accessed.

最後にアクセスされたファイルハンドルの現在の行番号。

Each filehandle in Perl counts the number of lines that have been read from it. (Depending on the value of $/, Perl's idea of what constitutes a line may not match yours.) When a line is read from a filehandle (via readline() or <>), or when tell() or seek() is called on it, $. becomes an alias to the line counter for that filehandle.

Perl の各ファイルハンドルは、そこから読み込んだ行数を数えています。 ($/ の値に依存して、何が行を構成するかに関する Perl の考えはあなたの 考えと一致しないかもしれません。) 行が(readline() や <> を使って)ファイルハンドルから読み込まれたか、 tell() や seek() がファイルハンドルに対して呼び出された場合、 $. はそのファイルハンドルの行カウンタへのエイリアスとなります。

You can adjust the counter by assigning to $., but this will not actually move the seek pointer. Localizing $. will not localize the filehandle's line count. Instead, it will localize perl's notion of which filehandle $. is currently aliased to.

$. へ代入することでカウンタの値を修正できますが、これは実際にシーク ポインタを動かすことはありません。 $. をローカル化してもファイルハンドルの行カウンタは ローカル化されません。 代わりに、現在 $. がどのファイルハンドルへのエイリアスかという情報が ローカル化されます。

$. is reset when the filehandle is closed, but not when an open filehandle is reopened without an intervening close(). For more details, see "I/O Operators" in perlop. Because <> never does an explicit close, line numbers increase across ARGV files (but see examples in "eof" in perlfunc).

$. はファイルハンドルがクローズされるとリセットされますが、 オープンしているファイルハンドルが close() されることなく再オープンされた 場合にはリセット されません。 さらなる詳細については、"I/O Operators" in perlop を参照してください。 なぜなら、 <> は決して明示的なクローズは行わず、行番号は ARGV の ファイル間で通算してカウントされるからです(但し "eof" in perlfunc の例を 参照してください)。

You can also use HANDLE->input_line_number(EXPR) to access the line counter for a given filehandle without having to worry about which handle you last accessed.

また、HANDLE->input_line_number(EXPR) とすることで、どのハンドルに 最後にアクセスしたかを気にすることなく行カウンタにアクセスできます。

Mnemonic: many programs use "." to mean the current line number.

記憶法: 多くのプログラムで "." が現在行番号を示すように使われています。

HANDLE->input_record_separator( EXPR )

$INPUT_RECORD_SEPARATOR

$RS

$/

The input record separator, newline by default. This influences Perl's idea of what a "line" is. Works like awk's RS variable, including treating empty lines as a terminator if set to the null string (an empty line cannot contain any spaces or tabs). You may set it to a multi-character string to match a multi-character terminator, or to undef to read through the end of file. Setting it to "\n\n" means something slightly different than setting to "", if the file contains consecutive empty lines. Setting to "" will treat two or more consecutive empty lines as a single empty line. Setting to "\n\n" will blindly assume that the next input character belongs to the next paragraph, even if it's a newline.

入力レコードセパレータで、デフォルトでは改行文字。 これは Perl での「行」とは何か、ということに影響を与えます。 空文字列に設定されると、空行をセパレータとして扱うことを 含めて、awk の変数 RS のように働きます。 (空行はスペースやタブを含んでいてはいけません。) 複数文字の区切文字を示すために、文字列を設定することもできます。 また、ファイルの最後まで読み込むために undef を指定することもできます。 この変数に "\n\n" を設定すると、空行が続く場合において、 "" を設定した場合とわずかに違う動作をするようになります。 "" を設定した場合には、複数の空行も 1 つの空行であるかのように扱います。 "\n\n" を設定した場合には、単純に次の文字が (たとえ改行文字であっても) 次の段落に含まれるものとして扱います。

    local $/;           # enable "slurp" mode
    local $_ = <FH>;    # whole file now here
    s/\n[ \t]+/ /g;

Remember: the value of $/ is a string, not a regex. awk has to be better for something. :-)

注意: $/ は文字列であり、正規表現ではありません。 awk は何かもっとうまくやらなくてはいけません。:-)

Setting $/ to a reference to an integer, scalar containing an integer, or scalar that's convertible to an integer will attempt to read records instead of lines, with the maximum record size being the referenced integer. So this:

$/ に整数、整数を含むスカラ、整数に変換できるスカラのいずれかへの リファレンスをセットすると、行を読む代わりにレコードを読もうとします。 この場合、最大レコードサイズはリファレンス先の整数値となります。つまり:

    local $/ = \32768; # or \"32768", or \$var_containing_32768
    open my $fh, "<", $myfile or die $!;
    local $_ = <$fh>;

will read a record of no more than 32768 bytes from FILE. If you're not reading from a record-oriented file (or your OS doesn't have record-oriented files), then you'll likely get a full chunk of data with every read. If a record is larger than the record size you've set, you'll get the record back in pieces. Trying to set the record size to zero or less will cause reading in the (rest of the) whole file.

これは FILE から 32768 バイトを超えないようにレコードを読み込みます。 もしレコード指向のファイルを読み込まない場合 (あるいは OS がレコード指向ファイルを持たない場合)、 読み込み毎にデータのチャンク全部を取り込みます。 もしレコードがセットしたレコードサイズより大きい場合、 レコードの部分を取り込みます。 レコードサイズを 0 以下にセットしようとすると、(残りの)ファイル全体を 読み込むことになります。

On VMS, record reads are done with the equivalent of sysread, so it's best not to mix record and non-record reads on the same file. (This is unlikely to be a problem, because any file you'd want to read in record mode is probably unusable in line mode.) Non-VMS systems do normal I/O, so it's safe to mix record and non-record reads of a file.

VMS では、レコード読み込みは sysread と等価に行われますので、 レコード読み込みと非レコード読み込みを同じファイルで混ぜないのが 最善です。(これはあまり問題になりません。なぜなら レコード読み込みしたいファイルは多分行モードでは使えないものだからです。) VMS 以外のシステムでは普通の I/O を使いますので、 同じファイルのレコード読み込みと非レコード読み込みを混ぜても安全です。

See also "Newlines" in perlport. Also see $..

"Newlines" in perlport と $. も参照してください。

Mnemonic: / delimits line boundaries when quoting poetry.

記憶法: /は、詩を引用するときに、行の区切りを示します。

Handle->output_record_separator( EXPR )

$OUTPUT_RECORD_SEPARATOR

$ORS

$\

The output record separator for the print operator. If defined, this value is printed after the last of print's arguments. Default is undef.

print 演算子のための出力レコードセパレータ。 もし定義されていると、print の最後の引数の最後にこの値が表示されます。 デフォルトは undef です。

Mnemonic: you set $\ instead of adding "\n" at the end of the print. Also, it's just like $/, but it's what you get "back" from Perl.

記憶法: print の最後に "\n" を付け加える代わりに $\ を設定する。 また、$/ に似通っているが、Perl から「バック」されるものです。

HANDLE->autoflush( EXPR )

$OUTPUT_AUTOFLUSH

$|

If set to nonzero, forces a flush right away and after every write or print on the currently selected output channel. Default is 0 (regardless of whether the channel is really buffered by the system or not; $| tells you only whether you've asked Perl explicitly to flush after each write). STDOUT will typically be line buffered if output is to the terminal and block buffered otherwise. Setting this variable is useful primarily when you are outputting to a pipe or socket, such as when you are running a Perl program under rsh and want to see the output as it's happening. This has no effect on input buffering. See "getc" in perlfunc for that. See "select" in perlfunc on how to select the output channel. See also IO::Handle.

0 以外に設定されると、 その時点で選択されている出力チャネルを 直ちにその場でフラッシュし、 さらに write や print を行なうごとに、強制的にフラッシュします。 デフォルトでは 0 となっています (チャンネルが実際にシステムによってバッファリングされているかどうかは 関知しません。$| は Perl が明示的に毎回書き込みの後に フラッシュするかどうかのみを示します)。 STDOUT は通常では、端末への出力時には行バッファリング、 それ以外ではブロックバッファリングであることに注意してください。 これは、Perl のスクリプトを rsh 配下で実行して、 実行状況を確認したい場合のように、パイプやソケットに出力するときに特に 便利でしょう。 これは入力バッファリングには何の影響も与えません。 出力チャネルの選択方法については "select" in perlfunc を参照してください。 IO::Handle も参照してください。

Mnemonic: when you want your pipes to be piping hot.

記憶法: パイプをホットな状態にしておくために使う。

フォーマット関連の変数¶

フォーマットのための特殊変数はファイルハンドルのための物のサブセットです。 Perl のフォーマットに関するさらなる情報については perlform を 参照してください。

$ACCUMULATOR

$^A

The current value of the write() accumulator for format() lines. A format contains formline() calls that put their result into $^A. After calling its format, write() prints out the contents of $^A and empties. So you never really see the contents of $^A unless you call formline() yourself and then look at it. See perlform and "formline PICTURE,LIST" in perlfunc.

format() 行のための、その時点での write() アキュムレータの値。 format には、$^A に結果を残す、formline() 呼び出しが含まれます。 自分のフォーマットを呼び出した後で、 write() は $^A の内容を出力してから消去します。 したがって、自分で formline() を呼び出すのでなければ、 $^A の値が見えることはありません。 perlform と "formline PICTURE,LIST" in perlfunc を参照してください。

HANDLE->format_formfeed(EXPR)

$FORMAT_FORMFEED

$^L

What formats output as a form feed. The default is \f.

フォーマット出力で、改ページのために出力されるもの。 デフォルトは \f。

HANDLE->format_page_number(EXPR)

$FORMAT_PAGE_NUMBER

$%

The current page number of the currently selected output channel.

その時点で選択されている出力チャネルの、その時点でのページ番号。

Mnemonic: % is page number in nroff.

記憶法: % は、nroff でのページ番号です。

HANDLE->format_lines_left(EXPR)

$FORMAT_LINES_LEFT

$-

The number of lines left on the page of the currently selected output

その時点で選択されている出力チャネルの、ページに残っている行数。 フォーマットで用いられます。

Mnemonic: lines_on_page - lines_printed.

記憶法: "ページ行数" - "印字済み行数"

Handle->format_line_break_characters EXPR

$FORMAT_LINE_BREAK_CHARACTERS

$:

The current set of characters after which a string may be broken to fill continuation fields (starting with ^) in a format. The default is " \n-", to break on a space, newline, or a hyphen.

フォーマットの充填継続フィールド (^ で始まるもの) への 文字列で行分割を許す文字集合。 デフォルトは " \n-" で空白、改行、ハイフンの後で行分割が可能となっています。

Mnemonic: a "colon" in poetry is a part of a line.

記憶法: 詩では「コロン」は、行の一部。

HANDLE->format_lines_per_page(EXPR)

$FORMAT_LINES_PER_PAGE

$=

The current page length (printable lines) of the currently selected output channel. The default is 60.

その時点で選択されている出力チャネルの、その時点での ページ長 (印字可能行数)。デフォルトは 60 です。 フォーマットで用いられます。

Mnemonic: = has horizontal lines.

記憶法: = には複数の水平線 (行) が含まれます。

HANDLE->format_top_name(EXPR)

$FORMAT_TOP_NAME

$^

The name of the current top-of-page format for the currently selected output channel. The default is the name of the filehandle with _TOP appended. For example, the default format top name for the STDOUT filehanlde is STDOUT_TOP.

その時点で選択されている出力チャネルの、その時点でのページ先頭 フォーマット名。 デフォルトは、ファイルハンドル名に _TOP を続けたものです。 例えば、STDOUT ファイルハンドルのデフォルトのページ先頭フォーマット名は STDOUT_TOP です。

Mnemonic: points to top of page.

記憶法: ページの先頭へのポインタ。

HANDLE->format_name(EXPR)

$FORMAT_NAME

$~

The name of the current report format for the currently selected output channel. The default format name is the same as the filehandle name. For example, the default format name for the STDOUT filehandle is just STDOUT.

その時点で選択されている出力チャネルの、その時点でのフォーマット名。 デフォルトは、ファイルハンドル名です。 例えば、STDOUT ファイルハンドルのデフォルトフォーマット名は 単に STDOUT です。

Mnemonic: brother to $^.

記憶法: $^ の兄弟。

エラー指示子¶

変数 $@, $!, $^E, $? は Perl プログラムの実行中に 発生した、異なる種類のエラー情報を保持します。 変数はエラーを報告した副システムと Perl プロセスとの「距離」 の順番に並んでいます。 これらはそれぞれ、Perl インタプリタ、C ライブラリ、 オペレーティングシステム、外部プログラムによって検出された エラーに対応しています。

これらの変数の違いを示すために、 以下のようなシングルクォートを用いた Perl 式を考えます。 この文の実行後、perl は四つ全ての特殊エラー変数をセットします:

        eval q{
                open my $pipe, "/cdrom/install |" or die $!;
                my @res = <$pipe>;
                close $pipe or die "bad pipe: $?, $!";
            };

eval() 式が実行されたとき、open(), <PIPE>, close は C ランタイムライブラリの呼び出しに変換され、それからオペレーティング システムコールに変換されます。 $! はこれらの呼び出しのどれかが失敗したとき、 C ライブラリの errno の値がセットされます。

$@ は eval された文字列がコンパイルされなかったとき (これは open か close が正しくない プロトタイプでインポートされたときに起こり得ます)、 または評価中に実行している Perl コードが die() したときにセットされます。 これらの場合には $@ の値はコンパイルエラー、または die への引数(これには $! と $? が差し挟まれます)です。 (しかし、Fatal も参照して下さい。)

いくつかのオペレーティングシステムでは、 $^E により詳細なエラー指示子が入っているかもしれません。 今回の場合で言えば、"CDROM tray not closed." などです。 追加のエラーメッセージに対応していないシステムでは、 $^E は $! と同じ値です。

最後に、$? は外部プログラム /cdrom/install が失敗したときに 非 0 にセットされるかもしれません。 上位の 8 ビットはプログラムが遭遇した特定のエラー状況 (プログラムの exit() の値)を反映します。 下位の 8 ビットは、シグナルの死亡やコアダンプ情報と言った失敗のモードを 反映します。 詳細については wait(2) を参照して下さい。 $! と $^E はエラー状況が検出されたときにのみ設定されますが、 変数 $? は wait やパイプの close の度に、前の値を上書きします。 これは、$@ が eval() の実行毎に、エラーならセットされ、 成功ならクリアされるという動作と似ています。

より詳細については、$@, $!, $^E, $? それぞれの説明を 参照して下さい。

${^CHILD_ERROR_NATIVE}

The native status returned by the last pipe close, backtick (``) command, successful call to wait() or waitpid(), or from the system() operator. On POSIX-like systems this value can be decoded with the WIFEXITED, WEXITSTATUS, WIFSIGNALED, WTERMSIG, WIFSTOPPED, WSTOPSIG and WIFCONTINUED functions provided by the POSIX module.

最後のパイプクローズ、逆クォート (``) コマンド、wait() と waitpid() の成功した呼び出し、system() 演算子から返された、 ネイティブなステータスです。 POSIX 風システムでは、この値は POSIX モジュールで提供される WIFEXITED, WEXITSTATUS, WIFSIGNALED, WTERMSIG, WIFSTOPPED, WSTOPSIG, WIFCONTINUED 関数でデコードできます。

Under VMS this reflects the actual VMS exit status; i.e. it is the same as $? when the pragma use vmsish 'status' is in effect.

VMS ではこれは実際の VMS の終了ステータスを反映します; 言い換えると、これは use vmsish 'status' プラグマが有効なときの $? と 同じです。

This variable was added in Perl 5.8.9.

この変数は Perl 5.8.9 で追加されました。

$EXTENDED_OS_ERROR

$^E

Error information specific to the current operating system. At the moment, this differs from $! under only VMS, OS/2, and Win32 (and for MacPerl). On all other platforms, $^E is always just the same as $!.

現在のオペレーティングシステムに特化したエラー情報です。 現在のところ、VMS, OS/2, Win32 (と MacPerl) のみで $! と異なる値をもちます。 その他のプラットフォームでは、$^E はいつも $! と同じです。

Under VMS, $^E provides the VMS status value from the last system error. This is more specific information about the last system error than that provided by $!. This is particularly important when $! is set to EVMSERR.

VMS では、$^E は最後のシステムエラーの VMS ステータス値です。 これは、最後のシステムエラーについて $! で提供されるものより 具体的な情報を示します。 これは特に $! が EVMSERR にセットされた場合に重要です。

Under OS/2, $^E is set to the error code of the last call to OS/2 API either via CRT, or directly from perl.

OS/2 では、$^E は CRT 経由、または Perl から直接呼び出された 最後の OS/2 API のエラーコードがセットされます。

Under Win32, $^E always returns the last error information reported by the Win32 call GetLastError() which describes the last error from within the Win32 API. Most Win32-specific code will report errors via $^E. ANSI C and Unix-like calls set errno and so most portable Perl code will report errors via $!.

Win32 では、$^E は Win32 API での最後のエラーの内容を返す GetLastError() Win32 呼び出しで報告される最新のエラー情報を 返します。 ほとんどの Win32 固有のコードはエラーを $^E 経由で返します。 ANSI C と Unix 風の呼び出しは errno をセットするので、 ほとんどの移植性のある Perl コードは $! 経由で エラーを報告します。

Caveats mentioned in the description of $! generally apply to $^E, also.

$! の説明で触れた問題点は一般的に $^E にも適用されます。

This variable was added in Perl 5.003.

この変数は Perl 5.003 で追加されました。

Mnemonic: Extra error explanation.

記憶法: 追加の(Extra)エラーの説明。

$EXCEPTIONS_BEING_CAUGHT

$^S

Current state of the interpreter.

現在のインタプリタの状態を示します。

        $^S         State
        ---------   -------------------
        undef       Parsing module/eval
        true (1)    Executing an eval
        false (0)   Otherwise

        $^S         状態
        ---------   -------------------
        undef       モジュール/eval のパース中
        真 (1)      eval の実行中
        偽 (0)      その他

The first state may happen in $SIG{__DIE__} and $SIG{__WARN__} handlers.

最初の状態は $SIG{__DIE__} と $SIG{__WARN__} のハンドラで起きる 可能性があります。

This variable was added in Perl 5.004.

この変数は Perl 5.004 で追加されました。

$WARNING

$^W

The current value of the warning switch, initially true if -w was used, false otherwise, but directly modifiable.

警告スイッチの値で、-w スイッチが使われると内部的に真となり、 そうでない場合は直接変更可能です。

See also warnings.

warnings も参照して下さい。

Mnemonic: related to the -w switch.

記憶法: -w スイッチに関係します。

${^WARNING_BITS}

The current set of warning checks enabled by the use warnings pragma. See the documentation of warnings for more details.

use warnings プラグマで有効にされた、現在の警告チェックの集合です。 詳細については warnings のドキュメントを参照して下さい。

This variable was added in Perl 5.10.

この変数は Perl 5.10 で追加されました。

$OS_ERROR

$ERRNO

$!

If used numerically, yields the current value of the C errno variable, or in other words, if a system or library call fails, it sets this variable. This means that the value of $! is meaningful only immediately after a failure:

数値として使われると、その時点の C の errno 変数の値が得られます; 言い換えると、もしシステムコールやライブラリ呼び出しが失敗すると、 この変数がセットされます。 これは、$! の値が意味を持つのは 失敗 の 直後 だけということを 意味します。

        if (open my $fh, "<", $filename) {
                # Here $! is meaningless.
                ...
    }
    else {
                # ONLY here is $! meaningful.
                ...
                # Already here $! might be meaningless.
    }
    # Since here we might have either success or failure,
    # here $! is meaningless.

The meaningless stands for anything: zero, non-zero, undef. A successful system or library call does not set the variable to zero.

meaningless は何でもあり得ます: 0、非 0、undef。 システムコールやライブラリ呼び出しが成功した場合は、この変数は 0 に セット されません。

If used as a string, yields the corresponding system error string. You can assign a number to $! to set errno if, for instance, you want "$!" to return the string for error n, or you want to set the exit value for the die() operator.

文字列として使われると、対応するシステムエラーのメッセージ文字列が得られます。 たとえば、$! にエラーの文字列を返して欲しいならば、あるいは、 die() 演算子の exit 値を設定するために、errno を設定するため $! へ代入を行なうことが可能です。

Mnemonic: What just went bang?

記憶法: 何が bang(!) したか。

%OS_ERROR

%ERRNO

%!

Each element of %! has a true value only if $! is set to that value. For example, $!{ENOENT} is true if and only if the current value of $! is ENOENT; that is, if the most recent error was "No such file or directory" (or its moral equivalent: not all operating systems give that exact error, and certainly not all languages). To check if a particular key is meaningful on your system, use exists $!{the_key}; for a list of legal keys, use keys %!. See Errno for more information, and also see "$!".

%! の各要素は、$! がその値にセットされている場合にのみ真の値を 持ちます。 例えば、$!{ENOENT} は、現在の $! の値が ENOENT の場合にのみ 真となります; これは、最近のエラーが "No such file or directory" (あるいは倫理的に等価なもの: 全ての OS が正確に 同じエラーを出すわけではないですし、全ての言語で出るわけでもありません) の 場合です。 あなたのシステムで特定のキーが意味があるかどうかを調べるには、 exists $!{the_key} を使ってください; 有効なキーのリストを得るには、 keys %! としてください。 さらなる情報に関しては Errno と /$! を参照してください。

This variable was added in Perl 5.005.

この変数は Perl 5.005 で追加されました。

$CHILD_ERROR

$?

The status returned by the last pipe close, backtick (``) command, successful call to wait() or waitpid(), or from the system() operator. This is just the 16-bit status word returned by the traditional Unix wait() system call (or else is made up to look like it). Thus, the exit value of the subprocess is really ($? >> 8), and $? & 127 gives which signal, if any, the process died from, and $? & 128 reports whether there was a core dump.

最後に close したパイプ、バッククォート (``) コマンド、 成功した wait() または waitpid() 呼び出し、system() 演算子が返した ステータス。 このステータスワードは伝統的な Unix の wait() システムコールが返した 16 ビットのステータス(またはそのように見えるもの)です。 従ってサブプロセスの exit 値は、実際には ($? >> 8) で、$? & 127 は、もしあれば、そのプロセスを止めたシグナルで、 $? & 128 はコアダンプがあるかどうかを示します。

Additionally, if the h_errno variable is supported in C, its value is returned via $? if any gethost*() function fails.

さらに、C で h_errno 変数に対応している場合は、 gethost*() が失敗したときに $? を通して返されます。

If you have installed a signal handler for SIGCHLD, the value of $? will usually be wrong outside that handler.

SIGCHLD のシグナルハンドラを設定した場合、 $? の値は通常ハンドラの外側では正しくない値となります。

Inside an END subroutine $? contains the value that is going to be given to exit(). You can modify $? in an END subroutine to change the exit status of your program. For example:

END サブルーチンの内側では $? には exit() に渡されようとしている 値を含みます。 プログラムの終了ステータスを変更するために、END サブルーチン 内で $? を変更できます。 例えば:

    END {
        $? = 1 if $? == 255;  # die would make it 255
    }

Under VMS, the pragma use vmsish 'status' makes $? reflect the actual VMS exit status, instead of the default emulation of POSIX status; see "$?" in perlvms for details.

VMS では、use vmsish 'status' を指定すると、 $? はPOSIX ステータスをエミュレートしたものではなく、 実際の VMS 終了ステータスを反映します; 詳細は "$?" in perlvms を 参照してください。

Mnemonic: similar to sh and ksh.

記憶法: sh や ksh と同様。

$EVAL_ERROR

$@

The Perl syntax error message from the last eval() operator. If $@ is the null string, the last eval() parsed and executed correctly (although the operations you invoked may have failed in the normal fashion).

最後の eval() 操作子による Perl の構文エラーメッセージです。 $@ が空文字列であれば、最後の eval() が正常に 解析され、実行されたことになります (が、実行した演算子が、 通常の意味で失敗しているかもしれません)。

Warning messages are not collected in this variable. You can, however, set up a routine to process warnings by setting $SIG{__WARN__} as described in "%SIG".

警告メッセージはこの変数に入りません。 しかし、"%SIG" に記述されている $SIG{__WARN__} にセットすることで 警告を処理するルーチンを設定できます。

Mnemonic: Where was the syntax error "at"?

記憶法: どこで ("at") 構文エラーが起ったか。

非推奨および削除された変数¶

非推奨となった変数は、perl のメンテナが最終的にこの変数を 削除するということを意図して通知されます。 その状態にも関わらず、まだ利用可能です。 非推奨となった変数を使うと警告が出ます。

変数が削除された後で変数を使うと、この変数が非対応となったことを 知らせるエラーが出ます。

エラーメッセージの詳細については perldiag を参照してください。

$OFMT

$#

$# was a variable that you could be use to format printed numbers. After a deprecation cycle, its magic was removed in Perl 5.10 and using it now triggers a warning: $# is no longer supported.

$# は、表示番号をフォーマットするために使われていました。 非推奨化の後、このマジックは Perl 5.10 で取り除かれ、警告を 引き起こします: $# is no longer supported.

This is not the sigil you use in front of an array name to get the last index, like $#array. That's still how you get the last index of an array in Perl. The two have nothing to do with each other.

これは $#array のように最後のインデックスを得るために配列名の前に付ける 印ではありません。 これは今でも Perl で配列の最後のインデックスを得る方法です。 これら二つには互いに何の関係もありません。

Deprecated in Perl 5.

Perl 5 で非推奨となりました。

Removed in Perl 5.10.

Perl 5.10 で削除されました。

$*

$* was a variable that you could use to enable multiline matching. After a deprecation cycle, its magic was removed in Perl 5.10. Using it now triggers a warning: $* is no longer supported. You should use the /s and /m regexp modifiers instead.

$* は複数行マッチングを有効にするために使われていた変数です。 非推奨化の後、このマジックは Perl 5.10 で削除されました。 これを使うと警告を引き起こします: $* is no longer supported。 代わりに /s と /m の正規表現修飾子を使うべきです。

Deprecated in Perl 5.

Perl 5 で非推奨となりました。

Removed in Perl 5.10.

Perl 5.10 で削除されました。

$ARRAY_BASE

$[

This variable stores the index of the first element in an array, and of the first character in a substring. The default is 0, but you could theoretically set it to 1 to make Perl behave more like awk (or Fortran) when subscripting and when evaluating the index() and substr() functions.

この変数は配列の最初の要素や、文字列の最初の文字のインデックスを 保管します。 デフォルトは 0 ですが、理論的には、index() 関数や substr() 関数を評価するときに、Perl の動作をより awk (や Fortran) に近づけるため、1 に設定することもできます。

As of release 5 of Perl, assignment to $[ is treated as a compiler directive, and cannot influence the behavior of any other file. (That's why you can only assign compile-time constants to it.) Its use is highly discouraged.

Perl 5 からは $[ への代入は、コンパイラ指示子として扱われ、 他のファイルの動作に影響を与えることがなくなりました。 (これが、コンパイル時定数しか代入できない理由です。) この変数の使用は非推奨です。

Prior to Perl 5.10, assignment to $[ could be seen from outer lexical scopes in the same file, unlike other compile-time directives (such as strict). Using local() on it would bind its value strictly to a lexical block. Now it is always lexically scoped.

Perl 5.10 より前では、$[ は(strict のような)その他のコンパイル時 指示子と異なり、同じファイルのレキシカルスコープの外側から見ることが 出来ていました。 これに local() を使うとこの値を厳密にレキシカルスコープの内側に限定します。 今では常にレキシカルスコープを持ちます。

Mnemonic: [ begins subscripts.

記憶法: [ は添え字付けの始め。

Deprecated in Perl 5.12.

Perl 5.12 で非推奨となりました。

$OLD_PERL_VERSION

$]

See $^V for a more modern representation of the Perl version that allows accurate string comparisons.

正確な文字列比較ができる、より近代的な Perl バージョンの表現については $^V を参照してください。

The version + patchlevel / 1000 of the Perl interpreter. This variable can be used to determine whether the Perl interpreter executing a script is in the right range of versions:

Perl インタプリタの version + patchlevel / 1000 が返されます。 スクリプトの最初で、そのスクリプトを実行しているインタプリタのバージョンが 適切な範囲内にあるかを調べる、といったことができます。 例:

    warn "No checksumming!\n" if $] < 3.019;

The floating point representation can sometimes lead to inaccurate numeric comparisons.

浮動小数点表現は数値比較が不正確になることがあります。 文字列比較が使える新しい Perl バージョンの表現方法である $^V を 参照して下さい。

See also the documentation of use VERSION and require VERSION for a convenient way to fail if the running Perl interpreter is too old.

実行する Perl インタプリタが古すぎる場合に終了する便利な方法に ついては use VERSION と require VERSION のドキュメントも 参照して下さい。

Mnemonic: Is this version of perl in the right bracket?

記憶法: Perl のバージョンは、正しい範囲 (right bracket) にあるか。

Deprecated in Perl 5.6.

Perl 5.6 で非推奨となりました。