名前¶

Storable - Perl データ構造体の永続化

概要¶

 use Storable;
 store \%table, 'file';
 $hashref = retrieve('file');

 use Storable qw(nstore store_fd nstore_fd freeze thaw dclone);

 # Network order
 nstore \%table, 'file';
 $hashref = retrieve('file');   # There is NO nretrieve()

 # ネットワーク順序
 nstore \%table, 'file';
 $hashref = retrieve('file');   # There is NO nretrieve()

 # Storing to and retrieving from an already opened file
 store_fd \@array, \*STDOUT;
 nstore_fd \%table, \*STDOUT;
 $aryref = fd_retrieve(\*SOCKET);
 $hashref = fd_retrieve(\*SOCKET);

 # 既にオープンされているファイルへ格納し、取り込みます
 store_fd \@array, \*STDOUT;
 nstore_fd \%table, \*STDOUT;
 $aryref = fd_retrieve(\*SOCKET);
 $hashref = fd_retrieve(\*SOCKET);

 # Serializing to memory
 $serialized = freeze \%table;
 %table_clone = %{ thaw($serialized) };

 # メモリへの直列化
 $serialized = freeze \%table;
 %table_clone = %{ thaw($serialized) };

 # Deep (recursive) cloning
 $cloneref = dclone($ref);

 # 深い(再帰的な)複写
 $cloneref = dclone($ref);

 # Advisory locking
 use Storable qw(lock_store lock_nstore lock_retrieve)
 lock_store \%table, 'file';
 lock_nstore \%table, 'file';
 $hashref = lock_retrieve('file');

 # アドバイザリロック
 use Storable qw(lock_store lock_nstore lock_retrieve)
 lock_store \%table, 'file';
 lock_nstore \%table, 'file';
 $hashref = lock_retrieve('file');

説明¶

Storable パッケージは、スカラ(SCALAR)、配列(ARRAY)、ハッシュ(HASH)、 オブジェクトのリファレンス(REF)を持った Perl のデータ構造体を永続化します。 つまり簡単にディスクに格納し、後で取り込むことを可能にします。

格納するオブジェクトへのリファレンスとイメージが書き込まれるファイル名を 指定して store を呼び出すという、通常の手続き的な方法で使うことが出来ます。

そのルーチンは I/O 障害や他の内部エラーが発生すると undef を返し、 そうでなければ真の値を返します。 重大なエラーは die 例外で伝えられます。

ディスクに格納されたデータを取り込むには、ファイル名を付けて retrieve を 使います。 そしてそのファイルに格納されたオブジェクトはメモリ上に再生成されます。 元になるオブジェクトへのリファレンスが返されます。 読込の途中でI/O エラーが発生すると、undef が代わりに返されます。 他の重大なエラーの場合には、エラーが die を通じて伝えられます。

格納が再帰的に行われるので、共通のデータの多くを共有しているオブジェクトへの リファレンスたちを１つの配列またはハッシュテーブルに詰め込んでしまい、 そのオブジェクトを格納したいと思うかもしれません。 この方法では、全体を 取り込んだときに、元々共有していたものを引き続き共有します。

ヘッダにちょっと手をいれると、store_fd ルーチンを使って既に開いている ファイル記述子に格納し、fd_retrieve を通じてファイルから 取り出すことができます。 それらの名前はデフォルトではインポートされません。 そのため、これらのルーチンが必要であれば、明示的に インポートしなければいけません。 指定するファイル記述子は、取り込むつもりであれば読み込み (read) で、 格納するつもりであれば書き込み (write) で、既に開かれていなければなりません。

        store_fd(\%table, *STDOUT) || die "can't store to stdout\n";
        $hashref = fd_retrieve(*STDIN);

複数のプラットフォームで共有することを簡単にしたり、リモートに 接続されていることが分かっているソケットに格納するときに、ネットワーク様式で 格納することも出来ます。 呼び出すルーチンには nstore と nstore_fd のように、頭に network を 表す n が付きます。 取り込むときはデータが正しく元に戻るので、取り込むのがネイティブからなのか、 ネットワーク様式のデータからなのかを知る必要はありません。 double(倍精度浮動小数点数型)の値も移植性が保証されるように 文字列化されます。 ただし最後の桁の精度が若干失われる危険性があります。

retrieve_fd を使うとき、オブジェクトは、対応する store_fd 毎、 一つのオブジェクト(つまり一つの再帰ツリー)を順番に取り込まれます。

さらにオブジェクト指向陣営寄りであれば、Storable を継承して、 store をメソッドとして呼び出すことにより、あなたのオブジェクトを 直接格納することができます。 格納されるツリーの元が bless された リファレンス(つまりオブジェクト)であれば、特別なケースになります。 そのため取込は、そのオブジェクトへのリファレンスを提供せず、 bless されたオブジェクトリファレンスを提供します。 (そうでなければ、そのblessされたオブジェクトへのリファレンスを 取得することにでしょう)

メモリへの格納¶

Storable エンジンは後から取り込むために、Perl スカラにデータを 格納することもできます。 これは主に複雑な構造体を安全で小さなメモリ空間に固めるため(freeze)に 使われます(構造体を固めると実際には直列化もされるので、他のプロセスに IPC を通じて送ることも潜在的には可能です)。 後で、そして多分どこか別のところで、Perl スカラを解凍(thaw)し、 元の複雑な構造体をメモリ上に再生成することができます。

驚いたことに、呼ばれるルーチンの名前は freeze と thaw といいます。 もし固めたスカラを他のマシンに送信したければ、代わりに nfreeze を ポータブルなイメージを取得してください。

オブジェクト構造を固め、すぐに解凍すると、実際には、その構造を深く 複写することを実現していることに注意して下さい：

    dclone(.) = thaw(freeze(.))

Storable は、中間のスカラを作成することなく、代わりに内部メモリ空間に 構造を固め、すぐに解凍する dclone インターフェイスを提供しています。

アドバイザリロック¶

lock_store と lock_nstore は store と nstore と同じです。 ただし、書き込む前に占有ロックを行います。 同様に lock_retrieve は retrieve のように動きます。 しかし読み込む前に共有ロックを行います。

全てのアドバイザリロックのスキームと同じように、保護はあなたが システマティックに lock_store と lock_retrieve を使うときにだけ 機能します。 もし他の部分が lock_retrieve を使っているときに、あなたの アプリケーションのある部分が store を使うと、何も保護されません。

アドバイザリロックの内部は Perl の flock() ルーチンを使って実装されます。 もしあなたのシステムが flock() のいかなる形式もサポートしていなかったり、 あなたのファイルを NFS 越しにファイルを共有しているのであれば、 ファイル記述子ではなくファイルシステムのエントリを使ってロックする LockFile:Simple のようなモジュールを使って他の形式のロックを 使いたいことでしょう。

スピード¶

スピードを上げるため、Storable の中核部分は C で書かれています。 Perl 内部を操作するとき、よりスピードを上げるためにカプセル化を 犠牲にするという、特別な低レベルの最適化がなされています。

規範形式¶

通常 Storable はハッシュを Perl が内部的に格納している順序で要素を格納します。 つまり疑似ランダムになります。 もし $Storable::canonical を TRUE 値に設定すると、 Storable はハッシュをそのキーの順に要素を格納します。 これにより、データ構造体を固められた形式で(または固められ圧縮された 形式でさえ)比較することができるようになります。 これは複雑な問い合わせのための参照テーブルを作るのに便利でしょう。

規範様式(=Canonical)はネットワーク様式を意味していません。 それらはまったく違う設定です。

コードリファレンス¶

Storable バージョン 2.05 から、コード(CODE)リファレンスが B::Deparse の 助けを借りて直列化できます。 この機能を有効にするためには、$Storable::Deparse を true 値に 設定してください。 非直列化を有効にするためには、$Storable::Eval が true 値に 設定されていなければなりません。 非直列化が eval を通して行われることに注意してください。 もし Storable ファイルに悪意のあるデータが入っていると危険です。 $Storable::Eval に eval の代わりに使われるサブルーチンリファレンスを 設定することができます。 コード(CODE)リファレンスの非直列化については、Safe コンポーネントを 使っている下記の例をご覧ください。

$Storable::Deparse や $Storable::Eval が偽の値に設定されると、 $Storable::forgive_me (後述) の値は直列化や逆直列化中に反映されます。

将来への互換性¶

今回の Storable のリリースでは、Perl のより新しいバージョンで以前の Perl では サポートされていなかったデータを直列化するために使うことができます。 デフォルトでは Storable は適切なことをしようとし、非直列化できない データにぶつかったら croak() します。 しかしデフォルトは以下のように変更することができます:

utf8 data

(utf8データ)

Perl 5.6 added support for Unicode characters with code points > 255, and Perl 5.8 has full support for Unicode characters in hash keys. Perl internally encodes strings with these characters using utf8, and Storable serializes them as utf8. By default, if an older version of Perl encounters a utf8 value it cannot represent, it will croak(). To change this behaviour so that Storable deserializes utf8 encoded values as the string of bytes (effectively dropping the is_utf8 flag) set $Storable::drop_utf8 to some TRUE value. This is a form of data loss, because with $drop_utf8 true, it becomes impossible to tell whether the original data was the Unicode string, or a series of bytes that happen to be valid utf8.

Perl 5.6 は 255 よりも大きなコード値を持つ Unicode 文字のサポートが 加わりました。 そして Perl 5.8 では、ハッシュキーでのフルサポートを持ちます。 Perl は内部的に、これらの文字を持つ文字列を utf8 を使ってエンコードします。 Storable は utf8 として、それらを直列化します。 デフォルトでは、より古いバージョンがそれが表すことが出来ない utf8 の値に ぶつかると、それは croak() します。 Storable が utf8 をバイトの文字列としてエンコードされたものとして 非直列化するよう、この動きを変更するためには、$Storable::drop_utf8 を 何らかの TRUE の値に設定してください。 これはデータが失われることになります。 というのも $drop_utf8 が true であると、もとのデータが Unicode 文字列だったのか、たまたま utf8 として正しいバイトの 並びだったのかが分からなくなってしまいます。

restricted hashes

(限定ハッシュ)

Perl 5.8 adds support for restricted hashes, which have keys restricted to a given set, and can have values locked to be read only. By default, when Storable encounters a restricted hash on a perl that doesn't support them, it will deserialize it as a normal hash, silently discarding any placeholder keys and leaving the keys and all values unlocked. To make Storable croak() instead, set $Storable::downgrade_restricted to a FALSE value. To restore the default set it back to some TRUE value.

Perl 5.8 は限定ハッシュ(restricted hash) のサポートを追加します。 それは与えられた集合にのみキーが制限され、値を読込のみに ロックすることが出来ます。 デフォルトではそれらをサポートしていない perl では Storable が 限定ハッシュにぶつかると、それを通常のハッシュとして非直列化します。 場所を保持するためのキーを全て黙って処分し、キーと値のロックを全て外します。 代わりに Storable に croak() させるためには、 $Storable::downgrade_restricted を FALSE の値に設定してください。 デフォルトの設定に戻すためには何らかの TRUE 値に戻してください。

files from future versions of Storable

(将来のバージョンの Storable からのファイル)

Earlier versions of Storable would immediately croak if they encountered a file with a higher internal version number than the reading Storable knew about. Internal version numbers are increased each time new data types (such as restricted hashes) are added to the vocabulary of the file format. This meant that a newer Storable module had no way of writing a file readable by an older Storable, even if the writer didn't store newer data types.

以前の Storable は、読んでいる Storable が知っているものより高い 内部バージョンを持ったファイルにぶつかるとすぐに croak しました。 内部バージョン番号は新しいデータ型(限定ハッシュのような)がファイル形式の 用語に加えられるたびに上がります。 これはより新しい Storable モジュールには、たとえ新しいデータ型を 格納しなかったとしても、古い Storable で読めるようなファイルを書く方法が ないことを意味します。

This version of Storable will defer croaking until it encounters a data type in the file that it does not recognize. This means that it will continue to read files generated by newer Storable modules which are careful in what they write out, making it easier to upgrade Storable modules in a mixed environment.

Storable のこのバージョンは、ファイルの中で、それが理解しないデータ型に ぶつかるまで croak しないという点で異なります。 つまりこれは出力するものに注意を払えば、新しい Storable モジュールで作られた ファイルでも読むことが出来るということです。 これにより混在する環境で Storable をアップグレードすることが簡単になります。

The old behaviour of immediate croaking can be re-instated by setting $Storable::accept_future_minor to some FALSE value.

$Storable::accept_future_minor を FALSE 値にすることにより、即座に croak するという Storable の古い動きに戻すことが出来ます。

これらの変数は関連する機能をサポートしている新しい Perl では何の効果も ありません。

エラーレポート¶

Storable は"例外"パラダイムを使っています。 それでは障害を回避しようとはしません: 何かよくないことが発生したら、呼び出した側の視点で例外が発生します (Carp と croak() をご覧ください)。 それらの例外を捕らえるために eval {} を使ってください。

Storable が croak するとき、Log::Agent パッケージが利用できるのであれば、 その logcroak() ルーチンを経由してエラーを報告しようとします。

通常のエラーは storable() や retrieve() に undef を返すことにより 報告されます。 そのようなエラーは通常 I/O のエラー(あるいは retrieve の際にストリームが 切り捨てられたか)です。

上級者のみ¶

フック¶

全てのクラスで、そのクラスのインスタンスを直列化や非直列化の処理の途中で 呼ばれるフックを定義することもできます。 それらのフックは実行される直列化を実行する方法を再定義することが出来ます。 (そのため、対になる非直列化も、そのように振舞わなければなりません)

前述の通り:

    dclone(.) = thaw(freeze(.))

フックについて述べたことはすべて、深いクローン作成にも当てはまります。 しかしフックには、その処理が単なるシリライゼーションなのかクローンなのかが わかります。

このため、直列化のフックが呼び出されるとになります。

    dclone(.) <> thaw(freeze(.))

同期を取ることもできます。 しかし誰か他の人が書いたクラスについて常に当てはまるような保証はありません。 さらに、そうすることによって得られるものはあまりありません: 直列化のフックは、 あるオブジェクトの一つの属性を保持することだけができます。 それは、その同じオブジェクトの深い複写の間に起きることとは多分、違います。

以下にフックのインターフェイスを示します：

STORABLE_freeze obj, cloning

The serializing hook, called on the object during serialization. It can be inherited, or defined in the class itself, like any other method.

直列化フック。 オブジェクトが直列化されるときに呼ばれます。 これは他のメソッドと同様に継承したり、クラスの中で再定義することができます。

Arguments: obj is the object to serialize, cloning is a flag indicating whether we're in a dclone() or a regular serialization via store() or freeze().

引数: obj は直列化するオブジェクト、cloning は dclone() の 中であるか、store() や freeze() を経由した通常の直列化かを示します。

Returned value: A LIST ($serialized, $ref1, $ref2, ...) where $serialized is the serialized form to be used, and the optional $ref1, $ref2, etc... are extra references that you wish to let the Storable engine serialize.

戻り値:リスト ($serialized, $ref1, $ref2, ...) 。 $serialized は、使われる直列化された形式、オプションの $ref1, $ref2 などは、 Storable エンジンに直列化させたい特別なリファレンスです。

At deserialization time, you will be given back the same LIST, but all the extra references will be pointing into the deserialized structure.

非直列化のときには、あなたは同じリスト(LIST)が与えられます。 しかし特別なリファレンスは全て非直列化された構造体を示します。

The first time the hook is hit in a serialization flow, you may have it return an empty list. That will signal the Storable engine to further discard that hook for this class and to therefore revert to the default serialization of the underlying Perl data. The hook will again be normally processed in the next serialization.

最初に フックが直列化の流れの中でヒットしたとき、あなたは空のリストを 返すことができます。 それはこのクラスのためのフックを、それから先、捨てらるよう Storable エンジンに 合図し、このため元になっている Perl データのデフォルトの直列化に戻ります。 そのフックは次の直列化では再び通常通り処理されます。

Unless you know better, serializing hook should always say:

よく分からなければ、直列化のフックは以下のようにするべきです:

    sub STORABLE_freeze {
        my ($self, $cloning) = @_;
        return if $cloning;         # Regular default serialization
        ....
    }

    sub STORABLE_freeze {
        my ($self, $cloning) = @_;
        return if $cloning;         # 通常のデフォルトの直列化
        ....
    }

in order to keep reasonable dclone() semantics.

dclone() の意味論でも合理的になるようにします。

STORABLE_thaw obj, cloning, serialized, ...

The deserializing hook called on the object during deserialization. But wait: if we're deserializing, there's no object yet... right?

オブジェクトが非直列化されるときに呼ばれる非直列化フック。 しかし待ってください: もし非直列化しているのであれば、 オブジェクトはまだないのでは...?

Wrong: the Storable engine creates an empty one for you. If you know Eiffel, you can view STORABLE_thaw as an alternate creation routine.

違います: Storable エンジンはあなたのために空のものを生成します。 Eiffel をご存知であれば、STORABLE_thaw は代替生成ルーチンとして みることが出来ます。

This means the hook can be inherited like any other method, and that obj is your blessed reference for this particular instance.

つまり、フックは他のメソッドと同じように継承することができ、 obj はこの特定のインスタンスのための bless されたリファレンスになります。

The other arguments should look familiar if you know STORABLE_freeze: cloning is true when we're part of a deep clone operation, serialized is the serialized string you returned to the engine in STORABLE_freeze, and there may be an optional list of references, in the same order you gave them at serialization time, pointing to the deserialized objects (which have been processed courtesy of the Storable engine).

その他の引数は STORABLE_freeze を知っていれば慣れているでしょう: 深い クローン処理の一部であれば cloning は真になります。 serialized は STORABLE_freeze でエンジンに返した直列化された 文字列です。 そしてオプションのリファレンスのリストもあるかもしれません。 それはシリアル化のときにあなたが与えた順番で、非直列化された オブジェクトを指します(それらは Storable エンジンによって特別に扱われます)。

When the Storable engine does not find any STORABLE_thaw hook routine, it tries to load the class by requiring the package dynamically (using the blessed package name), and then re-attempts the lookup. If at that time the hook cannot be located, the engine croaks. Note that this mechanism will fail if you define several classes in the same file, but perlmod warned you.

Storable エンジンが何も STORABLE_thaw フックルーチンを見つけられなければ、 それは動的にパッケージを(bless されたパッケージ名を使って) require することによりロードしようとします。 そして再び参照しようとします。 もしこの時点でフックが見つからなければ、エンジンは croak します。 この仕組は同じファイルでいくつものクラスを定義しているとうまくいきません。 しかし perlmod が警告するでしょう。

It is up to you to use this information to populate obj the way you want.

これらの情報を使って、どのように obj を作成するかは、あなた次第です。

Returned value: none.

戻り値: ありません。

STORABLE_attach class, cloning, serialized

While STORABLE_freeze and STORABLE_thaw are useful for classes where each instance is independent, this mechanism has difficulty (or is incompatible) with objects that exist as common process-level or system-level resources, such as singleton objects, database pools, caches or memoized objects.

STORABLE_freeze と STORABLE_thaw は、それぞれのインスタンスが 独立しているクラスには有用ですが、この機構は、 シングルトンオブジェクト、データベースプール、キャッシュ、メモ化 オブジェクトのような、プロセスレベルやシステムレベルで共通のリソースとして 存在しているオブジェクトについては問題(や非互換性)があります。

The alternative STORABLE_attach method provides a solution for these shared objects. Instead of STORABLE_freeze --> STORABLE_thaw, you implement STORABLE_freeze --> STORABLE_attach instead.

代替物である STORABLE_attach メソッドは、これらの共有オブジェクトのための 解法を提供します。 STORABLE_freeze --> STORABLE_thaw の代わりに、 STORABLE_freeze --> STORABLE_attach を実装します。

Arguments: class is the class we are attaching to, cloning is a flag indicating whether we're in a dclone() or a regular de-serialization via thaw(), and serialized is the stored string for the resource object.

引数: class はアタッチしたクラス、cloning は今 dclone() や thaw() 経由の正規逆直列化の中にいるかを示すフラグ、 serialized リソースオブジェクトのための保管した文字列です。

Because these resource objects are considered to be owned by the entire process/system, and not the "property" of whatever is being serialized, no references underneath the object should be included in the serialized string. Thus, in any class that implements STORABLE_attach, the STORABLE_freeze method cannot return any references, and Storable will throw an error if STORABLE_freeze tries to return references.

これらのリソースオブジェクトはプロセス/システム全体で所有されているもので、 何かの「属性」が直列化されているものではないと考えられているので、 オブジェクトの下のリファレンスは直列化した文字列に含まれるべきではありません。 従って、STORABLE_attach を実装しているクラスでは、 STORABLE_freeze メソッドはリファレンスを返すことはできず、 STORABLE_freeze がリファレンスを返そうとすると Storable はエラーを 投げます。

All information required to "attach" back to the shared resource object must be contained only in the STORABLE_freeze return string. Otherwise, STORABLE_freeze behaves as normal for STORABLE_attach classes.

共有リソースオブジェクトに戻すために必要な全ての情報は、 STORABLE_freeze の返り文字列 にのみ 含まれていなければ なりません。 さもなければ、STORABLE_freeze は STORABLE_attach クラスには 通常通りに振る舞います。

Because STORABLE_attach is passed the class (rather than an object), it also returns the object directly, rather than modifying the passed object.

STORABLE_attach は(オブジェクトではなく)クラスを渡されるので、 渡されたオブジェクトを修正したものではなくオブジェクトを直接返します。

Returned value: object of type class

返り値: オブジェクトの型 class

述語¶

述語(Predicates) はエクスポート可能ではありません。 それらは Storable パッケージ名を明示的に前につけて 呼び出されなければなりません。

Storable::last_op_in_netorder

The Storable::last_op_in_netorder() predicate will tell you whether network order was used in the last store or retrieve operation. If you don't know how to use this, just forget about it.

述語 Storable::last_op_in_netorder() は、最後の store あるいは retrieve 操作の際、ネットワーク順であったかを示します。 もしこの使い方がわからなければ、忘れてください。

Storable::is_storing

Returns true if within a store operation (via STORABLE_freeze hook).

(STORABLE_freeze フックを経由して)store 操作中であれば真を返します。

Storable::is_retrieving

Returns true if within a retrieve operation (via STORABLE_thaw hook).

(STORABLE_thaw フックを経由して)retrieve 操作中であれば真を返します。

再帰¶

フックによって Storable エンジンに再帰的に戻ってくることが可能になります。 実際、フックは通常の Perl コードです。 そして Storable は、あるものを直列化したり非直列化するときに便利です。 それならば、直列化された文字列を扱うために、それを 使っていけないなんてことあるんでしょうか？

しかしいくつか覚えておかなければならないことがあります:

• You can create endless loops if the things you serialize via freeze() (for instance) point back to the object we're trying to serialize in the hook.

  もし freeze() で直列化しようとしているものが、(例えば)フックの中で 直列化しようとしているオブジェクトを指しているとすると無限ループを 作ってしまうかもしれません。

• Shared references among objects will not stay shared: if we're serializing the list of object [A, C] where both object A and C refer to the SAME object B, and if there is a serializing hook in A that says freeze(B), then when deserializing, we'll get [A', C'] where A' refers to B', but C' refers to D, a deep clone of B'. The topology was not preserved.

  オブジェクト間で共有される参照は共有されなくなります: オブジェクト A と C の 両方が同じオブジェクト B を参照しているとき、オブジェクトのリスト [A, C] を 直列化し、そして A に freeze(B) と書いてある直列化のためのフックがあるなば、 非直列化すると、[A', C'] を取得し、A' は B' を参照します。 しかし C' は B' の深いクローンである D を参照します。 トポロジーは保持されません。

このために STORABLE_freeze は直列化するリファレンスのリストを 提供させているのです。 エンジンは他のオブジェクトと同じコンテキストの中で、それらが 直列化されることを、そのため共有されたオブジェクトは共有されたままに なることを保証します。

上記の [A, C] の例では、STORABLE_freeze フックは以下のように 返すことができます:

        ("something", $self->{B})

そして B 部分はエンジンによって直列化されます。 STORABLE_thaw では、非直列化された B' オブジェクトへのリファレンスを 取得するでしょう。

このため再帰は通常は避けられるはずです。 しかしそれでもサポートされています。

深いクローン作成¶

CPAN から、深いクローン作成をネイティブに、つまりメモリ上に固め、 その結果を解凍することがなしに実装する新しい Clone モジュールが利用できます。 それは将来、Storable の dclone() を置き換えることを目標にしています。 しかし、実行される深いクローン作成の方法を再定義するための Storable フックは、 まだサポートしていません。

Storable の magic¶

そう、それはたくさん:-)。 しかしより正確には、UNIX システムでは file と呼ばれるユーティリティが あります。 それはその内容(通常はその先頭の数バイト)をベースにデータファイルを 評価します。 これが機能するためには、magic と呼ばれる、あるファイルがそのデータの 特徴(signature)について教える必要があります。 その構成設定ファイルがある場所は UNIX の種類に依存し、 /usr/share/misc/magic や /etc/magic のようなところによくあります。 あなたのシステム管理者は magic ファイルを更新する必要があります。 必要な特徴情報は Storable::show_file_magic() を呼び出すことにより STDOUT へ 出力されます。 file ユーティリティ 3.38 以降のGNU の実装には、他の種類の Perl ファイルに 加えて、Stoable ファイルを評価するためのサポートが入っていると 期待することができます。

また、Storable イメージからファイルヘッダ情報を展開するために次の関数も 使えます:

$info = Storable::file_magic( $filename )

If the given file is a Storable image return a hash describing it. If the file is readable, but not a Storable image return undef. If the file does not exist or is unreadable then croak.

指定されたファイルが Storable イメージなら、それを記述したハッシュを 返します。 ファイルが読み込み可能だけれども Storable イメージでない場合、 undef を返します。 ファイルが存在しないか読み込みできない場合は、croak します。

The hash returned has the following elements:

返されるハッシュは以下の要素を持ちます:

version

This returns the file format version. It is a string like "2.7".

これはファイル形式バージョンを返します。 これは "2.7" のような文字列です。

Note that this version number is not the same as the version number of the Storable module itself. For instance Storable v0.7 create files in format v2.0 and Storable v2.15 create files in format v2.7. The file format version number only increment when additional features that would confuse older versions of the module are added.

このバージョン番号は Storable モジュール自身のバージョン番号と 同じではないことに注意してください。 例えば、Storable v0.7 は v2.0 形式のファイルを作り、 Storable v2.15 は v2.7 形式のファイルを作ります。 ファイル形式バージョン番号は、古いバージョンのモジュールが混乱するような 機能が追加されたときにだけインクリメントされます。

Files older than v2.0 will have the one of the version numbers "-1", "0" or "1". No minor number was used at that time.

v2.0 より前のファイルのバージョン番号は "-1", "0", "1" のいずれかです。 マイナー番号はこの時点では使われていません。

version_nv

This returns the file format version as number. It is a string like "2.007". This value is suitable for numeric comparisons.

これは数値としてのファイル形式バージョンを返します。 これは "2.007" のような文字列です。 この値は数値変換に適しています。

The constant function Storable::BIN_VERSION_NV returns a comparable number that represent the highest file version number that this version of Storable fully support (but see discussion of $Storable::accept_future_minor above). The constant Storable::BIN_WRITE_VERSION_NV function returns what file version is written and might be less than Storable::BIN_VERSION_NV in some configuations.

定数関数 Storable::BIN_VERSION_NV は、 このバージョンの Storable が対応している最大のバージョン番号を返します (しかし前述の $Storable::accept_future_minor の議論も参照してください)。 定数関数 Storable::BIN_WRITE_VERSION_NV は書かれるファイルのバージョンを 返します; これは設定によっては Storable::BIN_VERSION_NV よち 小さいかもしれません。

major, minor

This also returns the file format version. If the version is "2.7" then major would be 2 and minor would be 7. The minor element is missing for when major is less than 2.

これもファイル形式バージョンを返します。 バージョンが "2.7" の場合、major は 2 で minor は 7 です。 major が 2 より小さい場合は minor 要素はありません。

hdrsize

The is the number of bytes that the Storable header occupies.

これは Storable ヘッダが占めるバイト数です。

netorder

This is TRUE if the image store data in network order. This means that it was created with nstore() or similar.

これは、イメージが保管しているデータがネットワーク順序の場合は真です。 これは、nstore() のようなもので作られたということです。

byteorder

This is only present when netorder is FALSE. It is the $Config{byteorder} string of the perl that created this image. It is a string like "1234" (32 bit little endian) or "87654321" (64 bit big endian). This must match the current perl for the image to be readable by Storable.

これは、netorder が偽の場合にのみ存在します。 これはこのイメージが作成された perl の $Config{byteorder} 文字列です。 これは "1234" (32 ビットリトルエンディアン) や "87654321" (64 ビット ビッグエンディアン) のような文字列です。 イメージを Storable で読み込み可能であるためにはこれは現在の perl と 一致していなければなりません。

intsize, longsize, ptrsize, nvsize

These are only present when netorder is FALSE. These are the sizes of various C datatypes of the perl that created this image. These must match the current perl for the image to be readable by Storable.

これらは netorder が偽の場合にのみ存在します。 これらは、このイメージを作った perl の様々な C データ型のサイズです。 イメージが Storable で読み込み可能であるためには、これらは 現在の perl と一致していなければなりません。

The nvsize element is only present for file format v2.2 and higher.

nvsize 要素は、ファイル形式 v2.2 以降でのみ存在します。

file

The name of the file.

ファイルの名前。

$info = Storable::read_magic( $buffer )

$info = Storable::read_magic( $buffer, $must_be_file )

The $buffer should be a Storable image or the first few bytes of it. If $buffer starts with a Storable header, then a hash describing the image is returned, otherwise undef is returned.

$buffer は Storable のイメージかその最初の数バイトです。 $buffer が Storable のヘッダで始まっている場合、 イメージが表現しているハッシュが返され、さもなければ undef が返されます。

The hash has the same structure as the one returned by Storable::file_magic(). The file element is true if the image is a file image.

このハッシュは Storable::file_magic() で返されるものと同じ構造です。 イメージがファイルイメージの場合は file 要素は真です。

If the $must_be_file argument is provided and is TRUE, then return undef unless the image looks like it belongs to a file dump.

$must_be_file 引数が提供されてその値が真の場合、 イメージがファイルダンプに属するように見えない限り undef を返します。

The maximum size of a Storable header is currently 21 bytes. If the provided $buffer is only the first part of a Storable image it should at least be this long to ensure that read_magic() will recognize it as such.

Storable のヘッダの最大サイズは現在のところ 21 バイトです。 提供された $buffer が Storable イメージの最初の部分だけの場合、 read_magic() がこれを認識できるように、最低でもこの長さがある 必要があります。

例¶

Storable の使用法を示すコードサンプルを以下に示します:

        use Storable qw(store retrieve freeze thaw dclone);

        %color = ('Blue' => 0.1, 'Red' => 0.8, 'Black' => 0, 'White' => 1);

        store(\%color, 'mycolors') or die "Can't store %a in mycolors!\n";

        $colref = retrieve('mycolors');
        die "Unable to retrieve from mycolors!\n" unless defined $colref;
        printf "Blue is still %lf\n", $colref->{'Blue'};

        $colref2 = dclone(\%color);

        $str = freeze(\%color);
        printf "Serialization of %%color is %d bytes long.\n", length($str);
        $colref3 = thaw($str);

(私のマシンでの)出力結果：

        Blue is still 0.100000
        Serialization of %color is 102 bytes long.

Safe コンポーネント内でのコード(CODE)リファレンスの直列化と非直列化:

        use Storable qw(freeze thaw);
        use Safe;
        use strict;
        my $safe = new Safe;
        # because of opcodes used in "use strict":
        $safe->permit(qw(:default require));
        local $Storable::Deparse = 1;
        local $Storable::Eval = sub { $safe->reval($_[0]) };
        my $serialized = freeze(sub { 42 });
        my $code = thaw($serialized);
        $code->() == 42;

WARNING¶

ハッシュテーブルのキーとしてリファレンスを使っているならば、データを 取り出したときにガッカリするかもしれません。 実際のところ Perl はハッシュのキーとして使われているリファレンスを 文字列化します。 もし後で他のリファレンスの文字列化を通じて(つまり元々、ハッシュテーブルの 中に値を記録するためにキーとして使われたものと 同じリファレンスを使って)要素にアクセスしたければ、両方のリファレンスが 文字列化されたものが同じ文字列なので機能します。

しかし、store と retieve 操作をまたぐと動きません。 なぜなら取り込まれたオブジェクトでのアドレス(文字列化された リファレンスの一部です)が、おそらく元のアドレスとは違っているからです。 構造体の形は保持されますが、このような隠された意味は保存されません。

問題となるプラットフォームでは、Storable 関数に渡す記述子に binmode を 呼ぶようにして下さい。

データを規範形式で格納すると、大きなハッシュでは通常にデータを格納するのに 比べて非常に遅くなるかもしれません。 というのも各ハッシュのためのキーを保持するための一時的な配列を占有し、 生き延びさせ、ソートし、解放しなければならないためです。 いくつかのテストでは格納のスピードが半減しました-- どれくらい遅くなるかはデータの複雑さに依存します。 取り込みでは遅くなることはありません。

バグ¶

GLOB, FORMLINE 等は格納することが出来ません。 これらの操作のための意味をはっきり決めたら、それらを扱えるよう自由に Storable を拡張して下さい。

store 関数は、$Strable::forgive_me をなんらかの TRUE 値に 設定しておかなければ、それらのリファレンスに踏み込むと croak します。 その場合、警告で致命的なメッセージが返され、代わりに意味のない文字列が 格納されます。

$Storable::canonical を設定すると、数値が文字列化される可能性から 同じものであると比較される固められた文字列を作り出さないかもしれません。 スカラの文字列バージョンが存在するときには、それが格納される形式になります。 このため、もし同じデータ構造の 2 回固める操作をする間に、 たまたま数値を文字列として使ってしまうと、違う結果になります。

double(倍精度浮動小数点)をネットワーク様式で格納するとき、その値は テキストとして格納されます。 しかし、nstore()/retrieve() の組み合わせに正常に渡すことにより、無限や 「非数」のような数値でない浮動小数点を予想する必要はありません。

Storable は文字集合について知りませんし、気にもしません (それは文字が 8 ビットよりも大きいかもしれないということは知っています)。 ホストとターゲットシステムでの文字コードの解釈における違いは、 すべてあなたの問題です。 特にもしホストとターゲットが浮動小数点数のテキスト形式で異なる符号位置を 使うのであれば、nstore() を使ったとしても浮動小数点のデータを やりとりできないかもしれません。

Storable::drop_utf8 は鈍器のようなものです。 それには 全ての 文字列を utf8 の並びとして返すか、utf8 データを 8 ビットに 変換しようとし、変換に失敗したら croak() する以外に機能はありません。

Storable 2.01 より以前、格納時に符号付きと符号なし整数での区別は つけられませんでした。 デフォルトでは Storable は(もし持っていれば)スカラを文字列表現を選びます。 そのため文字列や浮動小数点数に変換されたことがない大きな符号なし整数を 格納するときにだけ問題になります。 言い換えれば、論理演算のような整数処理により作成され、格納の前に何も 文字列操作や算術コンテキストで使われなかった値です。

perl 5.6.0 と 5.6.1 での 64 ビットデータ¶

このセクションは、64 ビット整数(デフォルトではありません)に対応するように 構成設定されている Unix あるいは Linux 上の perl 5.6.0 や 5.6.1 で Storable 2.20 あるいはそれ以前によって出力された既存のデータを持っている 場合にのみ当てはまります。 ソースから独自の perl を構築するために Configure を実行するのではなく、 既にコンパイルされている perl を取得したのであれば、おそらく何も 影響はないでしょう。 そして、(あなたが疑問を持っていなければ) ここで読むのを止めることが出来ます。 Windows で perl を使っていれば、何も影響はありません。

Storable は、Storable を構築した C コンパイラのさまざまな C 言語の型の 大きさが入ったファイルヘッダを出力します。 そして同じ(あるいは互換性のある)アーキテクチャではない Storable によって 書かれたファイルをロードすることを拒絶します。 ファイルの中のさまざまなフィールドは C 言語の型の大きさによって与えられ、 そのため異なるアーキテクチャで書かれたファイルは互換性がないので、 このチェックとマシンのバイト順についてのチェックは必要です。 これはスピードを向上させるために行われます(ネットワーク順で出力するとき、 全てのフィールドは標準の長さでかかれます。 これは完全にネットワーク越えることを可能にしますが、読み込みと書き込みは より時間がかかります)

Perl 5.6.x は、perl インタプリタが 32 ビットシステムで 64 ビット整数を 格納できるスカラを可能にする C の long long 型を使う、オプションの 構成設定の機能を導入しました。 しかし Windows プラットフォーム以外で Perl 構成設定システムが C 構成 設定ファイルを生成した方法や、Storable がそのハンドラを生成する方法のために、 Storable は別にいくつかのデータをファイルに格納しているにも関わらず perl が 32 あるいは 64 ビット整数を使って出力したかは、 Storable ファイルヘッダの内容に反映されません。 このため 64 ビット整数で perl を実行している Storable は 32 ビット perl によって出力されたファイルからのヘッダを読み、データが実際には微妙に 互換性のないものであると理解せず、格納された整数にぶつかると恐ろしい間違いを 起こすでしょう(おそらくはクラッシュしてしまいます)。 これは設計上の失敗です。

Storable は現在は整数の大きさについての情報を持ったファイルヘッダを 出力し、読み込むように変更されています。 読み込まれた古いファイルが、32 ビット整数なのか 64 ビットなのかを 判定することはできません(同じヘッダを持っています)。 そのため自動的に正しい後方互換性モードに自動的に移ることはできません。 そのため Storable はデフォルトでは、新しい正しい動きをになっています。

これが意味することは、Unix あるいは Linux 上で 64 ビット整数で構成設定された perl 5.6.0 や 5.6.1 で実行した Storable 1.x によって書かれたデータを 持っているのであれば、デフォルトではこの Storable はそれを読み込むことを 拒絶し、Byte order is not compatible(バイト順に互換性がありません)という エラーになります。 もしそのようなデータを持っているのであれば、この Storable が古いヘッダを 持っているファイルを読み書きできるよう、$Storable::interwork_56_64bit を 真の値に設定しなければなりません。 あなたのデータやあなたが通信する古い perl を、Storable の現行バージョンに 移すこともしなければなりません。

上記で記述された特定の perl の構成設定で書かれたデータを持っていなければ、 何もしなくてもいいですし、するべきでもありません。 フラグを設定しないでください - 同じように構成設定された perl での Storable が、それらをロードすることを拒絶するだけでなく、違うように 構成設定された perl での Storable が、それらをそれにとって正しいものと信じて ロードし、読み込んでいる途中で失敗したり、クラッシュしてしまいます。

CREDITS¶

以下の方に感謝いたします (時系列順):

        Jarkko Hietaniemi <[email protected]>
        Ulrich Pfeifer <[email protected]>
        Benjamin A. Holzman <[email protected]>
        Andrew Ford <[email protected]>
        Gisle Aas <[email protected]>
        Jeff Gresham <[email protected]>
        Murray Nesbitt <[email protected]>
        Marc Lehmann <[email protected]>
        Justin Banks <[email protected]>
        Jarkko Hietaniemi <[email protected]> (AGAIN, as perl 5.7.0 Pumpkin!)
        Salvador Ortiz Garcia <[email protected]>
        Dominic Dunlop <[email protected]>
        Erik Haugan <[email protected]>

バグ報告、提案、貢献がありました。

Benjamin Holzman は tie された変数のサポートに貢献してくれました。 Andrew Ford はハッシュための標準様式に貢献してくれました。 そして Gisle Aas は Perl の内部についての私の誤解を修正し、タグをつける 代わりに単純にオブジェクトの数を数えることによって、 出力ストリームでの「タグ」の吐き出しを最適化してくれました。 (これによりバージョン 0.6 以降でバイナリでの Storable イメージの 互換性をなくすことになりました。 しかし古いイメージもまだきちんと理解されます)。 Murray Nesbitt は Storable をスレッドセーフにしてくれました。 Marc Lehmann は tie されている要素へのオーバーロードと参照のサポートを 追加してくれました。

作者¶

Storable は Raphael Manfredi <[email protected]> によって 作成されました。 現在、perl5-porters <[email protected]> によって保守されています。

障害、バグ修正、コメント、苦情などは、例え Raphael に送られるべき 賛辞であっても、私たちにメールしてください。 どうか障害について Raphael にメールしないでください。 彼はもう Storable について取り組んでいません。 そしてあなたのメッセージは彼が私たちに転送するまで遅れてしまいます。

SEE ALSO¶

Clone.